请能否给我一个flex NetConnect连接成功的例子

0 0

请能否给我一个flex NetConnect连接成功的例子5

我在网上找到很多关于flex NetConnect的例子，可是为什么我copy进去的代码在我的flex工程中确总是连接失败，我查了rtmp的端口确实没问题啊，后台日志也没有报什么错误，可是就在NetStream对象创建的时候创个NetConnect对象，这一边初始化的时候，后台日志报错，我郁闷，为什么别人用的好好的，而我却总是报些无聊的错误，求解啊！错误日志如下：
LCDS]Deserializing AMF/RTMP request
Version: 3 "createStream"
2.0

(Command method=createStream (3) trxId=2.0)
null

[LCDS]Received command: TCCommand [ Cmd: 3, MethodName: createStream, TrxID: 2.0]
[LCDS]Thread[my-rtmp-SocketServer-WorkerThread-2,5,main] failed to read Connection '11701859' or process the data; Connection is in the 'Open' state and will be forced closed.
java.lang.IndexOutOfBoundsException: Index: 0, Size: 0

Flash AIR

2011年10月04日 12:21

max_dong_max_1
23
0 0 0

2个答案按时间排序按投票排序

0 0

<?xml version="1.0" encoding="utf-8"?>
<panel:SuperPanel xmlns:fx="http://ns.adobe.com/mxml/2009"
xmlns:s="library://ns.adobe.com/flex/spark" creationComplete="init()"
xmlns:panel="com.blessedos.skins.panel.*" enable_full="false" enable_max="false"
xmlns:mx="library://ns.adobe.com/flex/mx" width="100%" height="100%">
<fx:Script>
<![CDATA[
import com.blessedos.common.component.DialogWindow;
import com.blessedos.common.util.BlessedAlert;
import com.blessedos.common.util.BusyStatus;

import mx.core.UIComponent;

import org.osmf.net.NetConnectionCodes;
import org.osmf.net.NetStreamCodes;
//revice开头的变量是接收端
public var recive_video:Video;
public var recive_ns:NetStream;
public var recive_netCon:NetConnection;
public var recive_ui:UIComponent;

//publish开头的变量是发布端
public var publish_video:Video;
public var publish_ns:NetStream;
public var publish_netCon:NetConnection;
public var cam:Camera;
public var mic:Microphone;
public var publish_ui:UIComponent;
/**
* 初始化发布端
*/
public function initPublish():void
{
/* 显示忙碌状态 */
BusyStatus.showBusy(publish);
/* 初始化乘放Video的容器 */
publish_ui = new UIComponent();
publish_ui.width = publish.width;
publish_ui.height = publish.height;
/* 实例化video */
publish_video = new Video(publish_ui.width,publish_ui.height);
publish_netCon = new NetConnection();
publish_netCon.client = this;
publish_netCon.addEventListener(NetStatusEvent.NET_STATUS,publish_netStatusHandler);
publish_netCon.connect("rtmp://192.168.0.138/live");
/* 将Video添加到容器上 */
publish_ui.addChild(publish_video);
publish.addElement(publish_ui);
}
/**
* 发布端的流媒体服务连接状态
*
*/
public function publish_netStatusHandler(event:NetStatusEvent):void
{
switch(event.info.code){
case NetConnectionCodes.CONNECT_SUCCESS:
/* 连接成功开始加载设备 */
/* 初始化设备和视频流连接 */
publish_ns = new NetStream(publish_netCon);
cam = Camera.getCamera();
mic = Microphone.getMicrophone();
publish_ns.attachAudio(mic);
publish_ns.attachCamera(cam);
cam.setMode(publish_video.width,publish_video.height,24);
cam.setQuality(0,100);
publish_ns.addEventListener(NetStatusEvent.NET_STATUS,publish_netStatusHandler);
publish_ns.publish("testlive","live");
publish_video.attachCamera(cam);
BusyStatus.removeBusy(publish);
break;
case NetConnectionCodes.CONNECT_FAILED:
BlessedAlert.show("流媒体连接失败","ERROR");
break;
case NetConnectionCodes.CONNECT_CLOSED:
BlessedAlert.show("流媒体连接成功关闭","INFO");
break;
case NetStreamCodes.NETSTREAM_PUBLISH_BADNAME:
BlessedAlert.show("该名称视频已在直播","INFO");
break;
default:
break;
}
}

public function onBWDone():void{
};

/**
* 初始化接收端
*/
public function initRecive():void
{
BusyStatus.showBusy(recive);
recive_ui = new UIComponent();
recive_ui.width = recive.width;
recive_ui.height = recive.height;
recive_video = new Video(recive_ui.width,recive_ui.height);
recive_netCon = new NetConnection();
recive_netCon.client = this;
recive_netCon.addEventListener(NetStatusEvent.NET_STATUS,recive_netStatusHandler);
recive_netCon.connect("rtmp://192.168.0.138/live");
recive_ui.addChild(recive_video);
recive.addElement(recive_ui);
}

/**
*
*/
public function recive_netStatusHandler(event:NetStatusEvent):void
{
switch(event.info.code){
case NetConnectionCodes.CONNECT_SUCCESS:
recive_ns = new NetStream(recive_netCon);
recive_ns.addEventListener(NetStatusEvent.NET_STATUS,recive_netStatusHandler);
recive_video.attachNetStream(recive_ns);
recive_ns.play("testlive");
BusyStatus.removeBusy(recive);
break;
default:
break;
}
}

public function init():void
{

}

]]>
</fx:Script>
<fx:Declarations>

</fx:Declarations>
<mx:VBox width="100%" height="100%">
<mx:HBox paddingBottom="20" paddingLeft="20" paddingRight="20" paddingTop="20" width="100%" height="100%" horizontalGap="20">
<s:BorderContainer id="publish" width="100%" height="100%" />
<s:BorderContainer id="recive" width="100%" height="100%" />
</mx:HBox>
<mx:HBox verticalAlign="middle" horizontalAlign="center" width="100%" height="30">
<s:Button label="开始播放" click="initPublish()"/>
<s:Button label="开始接收" click="initRecive()"/>
</mx:HBox>
</mx:VBox>
</panel:SuperPanel>

这是一个发布和接受的自定义组件里面的皮肤也是自定义的用的时候可以先把皮肤去掉修改一下rtmp的地址