AcheGesture 简介（使用方法 / 中文教程）

http://blog.zinewow.com/catalog.asp?tags=AcheGesture

基于Starling框架的AcheGesture是为基于Adobe AIR技术的移动应用提供的一套手势识别库。设计来源于苹果iOS开发框架的UIGestureRecognizers(Cocoa-Touch UIKit)。AcheGesture主要特性：

1、提供了最基本的几种手势，包括：Tap(轻击)、Double Tap(双击) 、Pinch(缩放)、Pan(拖拽)、Swipe(滑动)、Rotate(旋转)以及Long press(长按)。

2、提供针对每种手势的自定义配置，例如Long press的判别时间阈值(timeThreshold)。

3、处理手势之间的识别依赖(requireGestureRecognizerToFail)、识别优先级(priority)、同时作用(allowSimultaneous)等相互关系。

4、使用回调的机制传出手势（离散和连续）的所有识别状态：recognized、possible、failed、began、changed、ended和cancelled。

5、可扩展性，可以针对项目需求写手势识别扩展(GestureRecognizerPlugin)，并动态注入(activate)。

6、开源免费，可在任何场合和情况下使用。

为何要写AcheGesture

1、代码复用的需求：

Starling提供了Touch事件，包括了单点和多点的。但是对于某个具体的手势却没有做封装，例如常见的Swipe。对于每一种手势实现后的代码逻辑复用是最基本的封装需求。

2、手势识别复杂的依赖关系处理的需求：

第二个原因，也是非常重要的原因就是处理多种手势关系的需求。例如一个显示对象绑定了一个单击(Tap)和一个双击(Double Tap)，用户轻击两下，有以下可能：1、两个Tap和一个Double Tap，2、一个Tap和一个Double Tap 3、两个Tap，4、一个Double Tap。吃惊吗？竟然有四种，而且第2种可能相对比较难理解什么情况下发生的。其实一般情况下，我们期望得到的是第3和第4种。这就出现了手势识别依赖关系的需求。也就是说，Tap手势的识别依赖于Double Tap手势识别的失败(requireGestureRecognizerToFail)。通俗的说，就是，只有识别不出来Double Tap，Tap手势才能识别。多种手势的相互依赖关系使得手势的处理上复杂度提升，使得需要封装这样的逻辑统一处理。

3、多手势同时作用的需求： 

这也是一个非常常见的需求，但是如果只是一个Touch对象可能不能很方便的实现。就是例如使用Pinch手势的缩放的同时，还可能在Pan（拖拽移动）甚至还有可能使用Rotate同时进行旋转操作。

如何使用AcheGesture

Step1: 定义手势对象： 

以轻击（Tap）手势为例，此手势包含了两种状态，“识别”（recognized）和“可能识别”（possible），在TapGesture配置类中定义。所以首先定义手势对象，传入每个状态的回调函数。

private function linkGesture():void
{
    var g1:Gesture = new TapGesture(onTapRecognized, onTapPossible);
}

此处有两个回调函数，onTapRecognized和onTapPossible。对于这个手势的定义，其实也可以直接使用Object类型，这个对象需要包含各种识别状态的回调函数，例如”recognized”, “possible”等等。以刚才的那个Tap手势为例，g1可写成以下这种形式：

var g1:Object = {"recognized": onTapRecognized, "possible": onTapPossible};

建议使用acheGesture.data包下面的类型来定义每一种手势，除了有强类型提示的好处以外，也可以方便或者每种手势所包含的手势状态。以轻击(Tap)手势而言，就只有“识别”（recognized）和“可能识别”（possible）两种状态。

Step2: 绑定显示对象

接下来是使用GestureManager.add方法绑定定义的手势和目标显示对象。如下所示：

private function linkGesture():void
{
  var g1:Gesture = new TapGesture(onTapRecognized, onTapPossible);
  GestureManager.add(_btn, new GestureVars().onTap(g1).vars);
}

三个参数，第一个传入绑定的显示对象(Starling.display.DisplayObject)，第二个传入的是手势识别的配置对象，第三个参数是是否允许多个手势同时作用。和定义手势对象类似，此处使用的GestureVars去对配置属性进行强类型，其实也可以使用Object直接配置，如下代码所示：

GestureManager.add(_btn, {"tap": g1}, false);

所以如果都使用Object类型就可以简化写成：

GestureManager.add(_btn, {"tap": {"recognized": onTapRecognized, "possible": onTapPossible} }, false);

看个人喜好，建议使用acheGesture.data包下面的类型来强类型去配置手势。

Step3: 处理手势状态回调

所有的手势状态回调函数均接收一个参数，e: AcheGestureEvent，这个对象包含了手势状态回调会传出的一些属性，以Tap为例，在是否可能被识别（possible）状态，就是读取e.possible来确定如何显示按钮的状态。详细会在Tap手势的教程中介绍。

function onTapRecognized(e:AcheGestureEvent):void
{
  trace("tap gesture recognized!");
}
private function onTapPossible(e:AcheGestureEvent):void
{
  trace("tap gesture onTapPossible >>>" + e.possible);
}

了解设置后的期望值。

在使用手势库完成需求之前，需要了解某种绑定方式预期得到怎样的结果。以下面三种绑定方式为例，均是绑定了单击（Tap）和双击（Double Tap）只是在细节设置上不同。 

第一种，只是单单绑定了这两种手势，但是注意点是,add方法第三个参数传的是false，也就是说，同一个时刻不能多个手势同时作用，因为Tap和Double Tap都是在用户Touch Ended的时候来判断，所以，如果用户轻击两下，间隔时间符合双击，则收到一个双击，一个单击。注意是一个单击，因为第二个单击在判断的时候被双击优先判断了，所以不被识别。注意比较下面两种情况。

private function linkGesture1():void
{
  var g1:Gesture = new TapGesture(onTapRecognized);
  var g2:Gesture = new DoubleTapGesture(onDoubleTapRecognized);
  GestureManager.add(_btn, new GestureVars().onTap(g1).onDoubleTap(g2).vars,false);
}

第二种情况比较简单，就是，设置了add第三个参数为true，即，允许同时多个手势被识别，如果还像上一个那种操作情况，用户轻击两下，并且间隔时间符合双击的要求，则收到，两个单击和一个双击。也就是说这两种手势的识别互不干扰。各自识别各自的。

private function linkGesture2():void
{
  var g1:Gesture = new TapGesture(onTapRecognized);
  var g2:Gesture = new DoubleTapGesture(onDoubleTapRecognized)
  GestureManager.add(_btn, new GestureVars().onTap(g1).onDoubleTap(g2).vars, true);
}

第三种情况其实可能是我们想要的，就是设定了“依赖关系”，单机的识别依赖于双击的识别失败。还是像刚才那样操作，用户轻击两下，并且间隔时间符合双击的要求，此时收到的只是一次双击，没有单击。如果用户轻击一下，则在延迟一小段时间后收到单击。原因是，单击的识别需要等待双击识别失败（超过双击的时间间隔阈值）。

private function linkGesture3():void
{
  var g1:Gesture = new TapGesture(onTapRecognized);
  var g2:Gesture = new DoubleTapGesture(onDoubleTapRecognized)
  g1.requireGestureRecognizerToFail(g2);
  GestureManager.add(_btn, new GestureVars().onTap(g1).onDoubleTap(g2).vars);
}

不同的设置带来不同的结果，了解自己需要的结果和对应的设置方法才能正确使用AcheGesture。

备注：

其它关于 AcheGesture 的链接（含DEMO）：《Adobe AIR 移动开发：触摸、多点触控和手势输入》。

原文链接：http://www.tuicool.com/articles/UviyMr