WD4A Select Options 查询

使用Select Options查询首先要得到Select Options的值

method onactionsearch .
************************************************************************
* 按 select options 条件查询
* search 是事件名称 onaction是系统自动在事件名前加的作为方法名
* 建议尽量使用 in ranges 查询
************************************************************************
* 定义存储 select options 查询数据的 range table
  data: lt_r_form_app_tp type range of zcdm_form_app_tp, " 单据类型
        lw_r_form_app_tp like line of lt_r_form_app_tp.

  data: lt_r_app_topic_cd type range of zcdm_app_topic_cd, " 申请号
        lw_r_app_topic_cd like line of lt_r_app_topic_cd.

  data: lt_r_topic_type type range of zcdm_type_number,  " 重点选题类型
        lw_r_topic_type like line of lt_r_topic_type.

  data: lt_r_topic_level type range of zcdm_topic_level,  " 选题级别
        lw_r_topic_level like line of lt_r_topic_level.

  data: lt_r_app_status type range of zcdm_app_status,    " 审批状态
        lw_r_app_status like line of lt_r_app_status.

  data: lt_r_topic_name type range of zcdm_topic_name,   " 选题名称
        lw_r_topic_name like line of lt_r_topic_name.

  data: lt_r_apdat type range of zcdm_apdat,              " 申报日期
        lw_r_apdat like line of lt_r_apdat.

* 定义获取 select options 查询数据的 data 类型数据
  data: lr_range_table type ref to data,
        lr_parameter type ref to data.

* 定义分配 data 类型数据值的 field symbols ，like range table
  field-symbols: <fs_form_app_tp> like lt_r_form_app_tp,
                 <fs_topic_cd>    like lt_r_app_topic_cd,
                 <fs_topic_type>  like lt_r_topic_type,
                 <fs_topic_level> like lt_r_topic_level,
                 <fs_app_status>  like lt_r_app_status,
                 <fs_topic_name>  like lt_r_topic_name,
                 <fs_apdat>       like lt_r_apdat.

  data lo_nd_t_cot_form type ref to if_wd_context_node.
  data lo_el_t_cot_form type ref to if_wd_context_element.
  data ls_t_cot_form type wd_this->element_t_cot_form.
  data lt_t_cot_form type wd_this->elements_t_cot_form.

  data: index type i.

* navigate from <CONTEXT> to <T_COT_FORM> via lead selection
  lo_nd_t_cot_form = wd_context->get_child_node(
                       name = wd_this->wdctx_t_cot_form ).

* 获取单据类型值
  call method wd_this->select_options->get_range_table_of_sel_field
    exporting
      i_id           = 'APP_TP'
    receiving
      rt_range_table = lr_range_table.

  assign lr_range_table->* to <fs_form_app_tp>.
  append lines of <fs_form_app_tp> to lt_r_form_app_tp.
  unassign <fs_form_app_tp>.

* 获取申请号值
  call method wd_this->select_options->get_range_table_of_sel_field
    exporting
      i_id           = 'APP_CD'
    receiving
      rt_range_table = lr_range_table.

  assign lr_range_table->* to <fs_topic_cd>.
  append lines of <fs_topic_cd> to lt_r_app_topic_cd.
  unassign <fs_topic_cd>.

* 获取选题类型值
  call method wd_this->select_options->get_range_table_of_sel_field
    exporting
      i_id           = 'TOP_TP'
    receiving
      rt_range_table = lr_range_table.

  assign lr_range_table->* to <fs_topic_type>.
  append lines of <fs_topic_type> to lt_r_topic_type.
  unassign <fs_topic_type>.

* 获取选题级别值
  call method wd_this->select_options->get_range_table_of_sel_field
    exporting
      i_id           = 'TOP_LE'
    receiving
      rt_range_table = lr_range_table.

  assign lr_range_table->* to <fs_topic_level>.
  append lines of <fs_topic_level> to lt_r_topic_level.
  unassign <fs_topic_level>.

* 获取选题名称值
  call method wd_this->select_options->get_range_table_of_sel_field
    exporting
      i_id           = 'TOP_NM'
    receiving
      rt_range_table = lr_range_table.

  assign lr_range_table->* to <fs_topic_name>.
  append lines of <fs_topic_name> to lt_r_topic_name.
  unassign <fs_topic_name>.

* 获取审批状态值
  call method wd_this->select_options->get_range_table_of_sel_field
    exporting
      i_id           = 'APP_STA'
    receiving
      rt_range_table = lr_range_table.

  assign lr_range_table->* to <fs_app_status>.
  append lines of <fs_app_status> to lt_r_app_status.
  unassign <fs_app_status>.

* 获取选题名称值
  call method wd_this->select_options->get_range_table_of_sel_field
    exporting
      i_id           = 'APDAT'
    receiving
      rt_range_table = lr_range_table.

  assign lr_range_table->* to <fs_apdat>.
  append lines of <fs_apdat> to lt_r_apdat.
  unassign <fs_apdat>.

* 查询符合条件的重点选题计划单据
  select *
    into corresponding fields of table lt_t_cot_form
    from zcdm_t_cot_form
    where z_form_app_tp  in lt_r_form_app_tp
      and z_app_topic_cd in lt_r_app_topic_cd
      and z_topic_type   in lt_r_topic_type
      and z_topic_name   in lt_r_topic_name
      and z_app_status   in lt_r_app_status
      and z_apdat        in lt_r_apdat
      and z_crusr = sy-uname.

* 不同审批状态有不同button
  loop at lt_t_cot_form into ls_t_cot_form.
    index = sy-tabix.

    if ls_t_cot_form-z_app_status = '10'.             " 未通过
*     设置button1
      ls_t_cot_form-visible1 = '02'.
      ls_t_cot_form-image1   = 'ICON_SYSTEM_COPY'.
      ls_t_cot_form-text1    = '复制'.
*     设置button2
      ls_t_cot_form-visible2 = '01'.
      ls_t_cot_form-image2   = ''.
      ls_t_cot_form-text2    = ''.
    elseif ls_t_cot_form-z_app_status = '30'.        " 未提交
*     设置button1
      ls_t_cot_form-visible1 = '02'.
      ls_t_cot_form-image1   = 'ICON_CHANGE'.
      ls_t_cot_form-text1    = '修改'.
*     设置button2
      ls_t_cot_form-visible2 = '02'.
      ls_t_cot_form-image2   = 'ICON_DELETE'.
      ls_t_cot_form-text2    = '删除'.
    else.                                            " 审批中；已通过
*     设置button1
      ls_t_cot_form-visible1 = '01'.
      ls_t_cot_form-image1   = ''.
      ls_t_cot_form-text1    = ''.
*     设置button2
      ls_t_cot_form-visible2 = '01'.
      ls_t_cot_form-image2   = ''.
      ls_t_cot_form-text2    = ''.
    endif.

    modify lt_t_cot_form from ls_t_cot_form index index.
    clear: ls_t_cot_form , index.
  endloop.

* 绑定结果到节点
  lo_nd_t_cot_form->bind_table( lt_t_cot_form ).
  clear lt_t_cot_form.
  lo_nd_t_cot_form->get_static_attributes_table(
    importing
      table = lt_t_cot_form ).
endmethod.