【飞天奔月出品】feilong-nginx-manager.bat v2.0 windows版nginx 快速操控神器

接上一个版本 http://feitianbenyue.iteye.com/blog/2207061

 

 

原作者 :leleroyn
地址: 
http://www.cnblogs.com/leleroyn/archive/2010/07/08/1773388.htm#2634139

 

 

我借鉴了他的代码,  扩展了新的特性:

 

1.支持文件夹路径带空格,

2.显示nginx现在的进程

3.精简了 代码

 

 

先较于 上一个版本  http://feitianbenyue.iteye.com/blog/1828929 有以下更新:

1.新增 [5] 重新加载Nginx配置文件 (修改了nginx配置文件, 只需要 reload 下, 不需要重启nginx)

2.新增 [6] 检查测试nginx配置文件

3.新增 [7] 查看nginx version

 

什么都不说 ,上图:

 
 什么都不说,上原码:

 

 

@echo off
rem 提供Windows下nginx的启动，重启，关闭功能

echo ==================begin========================

cls 

color 0a 
TITLE Nginx 管理程序 Power By Ants (http://leleroyn.cnblogs.com) Update by 鑫哥

CLS 

echo. 
echo. ** Nginx 管理程序 Power By Ants (http://leleroyn.cnblogs.com)  *** 
echo. *** update by 鑫哥 2013-12-14 *** 
echo. 

::*************************************************************************************************************
::ngxin 所在的盘符
set NGINX_PATH=D:

::nginx 所在目录
set NGINX_DIR=D:\FeiLong Soft\Essential\Development\nginx-1.2.5\

::*************************************************************************************************************
:MENU 

echo. ***** nginx 进程list ****** 
::tasklist|findstr /i "nginx.exe"
tasklist /fi "imagename eq nginx.exe"

echo. 

    if ERRORLEVEL 1 (
        echo nginx.exe不存在
    ) else (
        echo nginx.exe存在
    )

echo. 
::*************************************************************************************************************
echo. 
	echo.  [1] 启动Nginx  
	echo.  [2] 关闭Nginx  
	echo.  [3] 重启Nginx 
	echo.  [4] 刷新控制台  
	echo.  [5] 重新加载Nginx配置文件
	echo.  [6] 检查测试nginx配置文件
	echo.  [7] 查看nginx version
	echo.  [0] 退 出 
echo. 

echo.请输入选择的序号:
set /p ID=
	IF "%id%"=="1" GOTO start 
	IF "%id%"=="2" GOTO stop 
	IF "%id%"=="3" GOTO restart 
	IF "%id%"=="4" GOTO MENU
	IF "%id%"=="5" GOTO reloadConf 
	IF "%id%"=="6" GOTO checkConf 
	IF "%id%"=="7" GOTO showVersion 
	IF "%id%"=="0" EXIT
PAUSE 

::*************************************************************************************************************
::启动
:start 
	call :startNginx
	GOTO MENU

::停止
:stop 
	call :shutdownNginx
	GOTO MENU

::重启
:restart 
	call :shutdownNginx
	call :startNginx
	GOTO MENU

::检查测试配置文件
:checkConf 
	call :checkConfNginx
	GOTO MENU

::重新加载Nginx配置文件
:reloadConf 
    call :checkConfNginx
	call :reloadConfNginx
	GOTO MENU
	
::显示nginx版本
:showVersion 
    call :showVersionNginx
	GOTO MENU	
	
	
::*************************************************************************************
::底层
::*************************************************************************************
:shutdownNginx
	echo. 
	echo.关闭Nginx...... 
	taskkill /F /IM nginx.exe > nul
	echo.OK,关闭所有nginx 进程
	goto :eof

:startNginx
	echo. 
	echo.启动Nginx...... 
	IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe"不存在
        goto :eof
     )

	%NGINX_PATH% 
	cd "%NGINX_DIR%" 

	IF EXIST "%NGINX_DIR%nginx.exe" (
		echo "start '' nginx.exe"
		start "" nginx.exe
	)
	echo.OK
	goto :eof
	
 
:checkConfNginx
	echo. 
	echo.检查测试 nginx 配置文件...... 
	IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe"不存在
        goto :eof
     )

	%NGINX_PATH% 
	cd "%NGINX_DIR%" 
	nginx -t -c conf/nginx.conf
 
	goto :eof
	
::重新加载 nginx 配置文件
:reloadConfNginx
	echo. 
	echo.重新加载 nginx 配置文件...... 
	IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe"不存在
        goto :eof
     )

	%NGINX_PATH% 
	cd "%NGINX_DIR%" 
	nginx -s reload
 
	goto :eof
	
::显示nginx版本
:showVersionNginx
	echo. 
	%NGINX_PATH% 
	cd "%NGINX_DIR%" 
	nginx -V
 	goto :eof

 

 

附件下载之后, 

 

根据自己nginx安装情况,  修改下  附件 bat 里面 这两个参数 

 

::ngxin 所在的盘符
set NGINX_PATH=D:

::nginx 所在目录
set NGINX_DIR=D:\FeiLong Soft\Essential\Development\nginx-1.2.5\

 

 

什么都不说,上附件:

评论

1 楼 lvhjean 2017-08-10  

如果放到Nginx所在磁盘可以简单调整，这样就不用改直接用了。哇咔咔。。。

::ngxin 所在的盘符  
set NGINX_PATH=%~d0 
  
::nginx 所在目录  
set NGINX_DIR=%~dp0