【飞天奔月出品】windows版nginx 快速操控神器(启动start,关闭stop,重启restart) 批处理

新版本 见  http://feitianbenyue.iteye.com/blog/2207061

 

 

 ---------------------------------------------------------------------------------------------------

 

原作者 :leleroyn

地址:

 

http://www.cnblogs.com/leleroyn/archive/2010/07/08/1773388.htm#2634139

 

 

我借鉴了他的代码,  扩展了新的特性:

 

1.支持文件夹路径带空格,

2.显示nginx现在的进程,

3.精简了 代码

 

什么都不说 ,上图:

 

 

 

什么都不说,上原码:

 

@echo off
rem 当前bat的作用

echo ==================begin========================

cls 
SET NGINX_PATH=D:
SET NGINX_DIR=D:\FeiLong Soft\Essential\Development\nginx-1.2.5\
color 0a 
TITLE Nginx 管理程序 Power By Ants (http://leleroyn.cnblogs.com)

CLS 

ECHO. 
ECHO. * * Nginx 管理程序 Power By Ants (http://leleroyn.cnblogs.com)  *  
ECHO. * update by 鑫哥 2013-03-13 *  
ECHO. 

:MENU 

ECHO. * nginx 进程list *  
tasklist|findstr /i "nginx.exe"

if ERRORLEVEL 1 (echo nginx.exe不存在) else (echo nginx.exe存在)


ECHO. 
	ECHO.  [1] 启动Nginx  
	ECHO.  [2] 关闭Nginx  
	ECHO.  [3] 重启Nginx  
	ECHO.  [4] 退 出 
ECHO. 

ECHO.请输入选择项目的序号:
set /p ID=
	IF "%id%"=="1" GOTO start 
	IF "%id%"=="2" GOTO stop 
	IF "%id%"=="3" GOTO restart 
	IF "%id%"=="4" EXIT
PAUSE 

:start 
	call :startNginx
	GOTO MENU

:stop 
	call :shutdownNginx
	GOTO MENU

:restart 
	call :shutdownNginx
	call :startNginx
	GOTO MENU

:shutdownNginx
	ECHO. 
	ECHO.关闭Nginx...... 
	taskkill /F /IM nginx.exe > nul
	ECHO.OK,关闭所有nginx 进程
	goto :eof

:startNginx
	ECHO. 
	ECHO.启动Nginx...... 
	IF NOT EXIST "%NGINX_DIR%nginx.exe" ECHO "%NGINX_DIR%nginx.exe"不存在 

	%NGINX_PATH% 

	cd "%NGINX_DIR%" 

	IF EXIST "%NGINX_DIR%nginx.exe" (
		echo "start '' nginx.exe"
		start "" nginx.exe
	)
	ECHO.OK
	goto :eof

 

 

什么都不说,上附件:

 

 

 

 

评论

2 楼 zyengogo 2014-07-18  

感谢楼主啊

1 楼 hsb0307 2013-04-03  

很有帮助啊，谢谢