Box2D物理引擎的使用方法

转：http://www.toswf.com/blog/blogview.asp?logID=103

众所周知的Box2DFlash是一款不错的物理引擎，如果我们了解了他的使用的技巧，我们也可以做出不错效果。
接下来，我会教大家如何使用它。为了能够使用这个物理引擎，我们首先必须全部的导入它的文件，如果在你的项目文件中有349K，你就可以导入了，如下所示：
import flash.display.Sprite;
import flash.events.Event;
// Classes used in this example
import Box2D.Dynamics.*;
import Box2D.Collision.*;
import Box2D.Collision.Shapes.*;
import Box2D.Common.Math.*;
导入的方法很简单吧！现在，我们创建一个b2World的对象（类所在的源文件在Box2D/Dynamic/b2World.as中）。这个全局的对象是整个body的引擎，任何的功能都是在这里面完成。
注意：这个引擎的"大脑"是b2BroadPhase.as，核心是Step()函数绑定的全局对象。千万不要忘了他的"大脑"：b2BroadPhase.as，否则你将会弄乱整个引擎。
全局的对象的构造函数作了三件事情：
1、一个在b2AABB类中的实例构建的坐标系统
2、一个定义重力的向量，这是一个b2Vec2类构建的实例。
3、一个布尔变量来定义对象是否"沉迷"。（如果你设置为true，对象将会沉迷）。
// create world AABB
var worldAABB:b2AABB = new b2AABB();
worldAABB.minVertex.Set(-1000.0, -1000.0);
worldAABB.maxVertex.Set(1000.0, 1000.0);
// Define the gravity vector
var gravity:b2Vec2 = new b2Vec2(0.0, 300.0);
// Allow bodies to sleep
var doSleep:Boolean = true;
// Construct a world object
m_world = new b2World(worldAABB, gravity, doSleep);
我的例子并不是我自己特有的，我所展示的代码从他们给引擎提供的"Hello World"代码中摘录下来的。
在创建了一个world的对象以后，你还要带给它生命，让的心脏跳动：
// Add event for main loop
addEventListener(Event.ENTER_FRAME, updating, false, 0, true);
public function updating(e:Event):void{
m_world.Step(m_timeStep, m_iterations);
}
执行Step()函数，每一帧都会更新所有的Body在world中的位置。
虽然现在的world中是空的，但是你可以往里面添加任何的球体或者盒子，以及你想到的任何形状的东西，我们需要定义一个Body。
一个body体大概需要做2-4件事情：
1、定义一个形状。
2、一个（x,y）的位置
下面的定义可选：
3、角度
4、一个预制的Sprite对象。
在Box2DFlash的例子中，你可能注意到所有的形状都是简单的。这是因为所有的东西在每一帧都是被线条重绘。
如果你想在你的游戏或者其他的什么中具有一些有特色的东西，你可以通过综合形状定义Body来制作一个Sprite。
在"HelloWorld"的例子中，他们使用Sprites来显示他们的对象。你也有可能把他们设置为不可见了，除非你真的想这么做，因为他们仍让会参与到计算当中。
有一些事情是很重要的，例如形状的定义，我们有3种类型的形状定义，他们都是扩展的b2ShapeDef基类。
我们先来说b2BoxDef类，这个具有4个重要的属性：
1、Extents:这是一个向量，本质上说他就是一个形状的中心坐标
2、Density:在碰撞的等式中我们使用密度*面积=质量，密度如果是0或者null,将会是一个静止的对象。
3、Friction:这用来计算两个对象之间的摩擦，你可以在0.0-1.0之间调整它们。
4、Restitution:这是调整对象弹性程度的属性，你可以在0.0-1.0之间调整它们。
b2CircleDef类中有一个不同的属性，代替Extents是他的半径。
b2PolyDef类具有一个顶点数组（最大是8）来代替Extents和Radius。这些顶点都是b2Vec2类型的对象。
现在，往world中添加一堆对象应该不是问题了：
var bodyDef:b2BodyDef;
var boxDef:b2BoxDef;
var circleDef:b2CircleDef;
// Add ground body
bodyDef = new b2BodyDef();
boxDef = new b2BoxDef();
boxDef.extents.Set(1000, 100);
boxDef.friction = 0.3;
/*Notice that the ground object has no density like the later
definitions. That's because it is static and we don't want it
effected by any forces.*/
bodyDef.position.Set(320, 400);
bodyDef.AddShape(boxDef);
// Add sprite to body userData
/*We have a Sprite object in the library called PhysGround. Here
we are associating that with our body definition.*/
bodyDef.userData = new PhysGround();
bodyDef.userData.width = boxDef.extents.x * 2;
bodyDef.userData.height = boxDef.extents.y * 2;
addChild(bodyDef.userData);
m_world.createBody(bodyDef);
// Add some objects
for (var i:int = 1; i < 20; i++){
/*We are going to re-use the same bodyDef from before.
It doesn't matter now, because it's already been copied and stored
in our world object.*/
bodyDef = new b2BodyDef();
// Box
if (Math.random() < 0.5){
boxDef = new b2BoxDef();
boxDef.extents.Set(Math.random() * 15 + 10, Math.random() * 15 + 10);
boxDef.density = 1.0;
boxDef.friction = 0.5;
boxDef.restitution = 0.2;
bodyDef.AddShape(boxDef);
/*We have a Sprite object in the library called PhysBox.*/
bodyDef.userData = new PhysBox();
bodyDef.userData.width = boxDef.extents.x * 2;
bodyDef.userData.height = boxDef.extents.y * 2;
}
// Circle
else {
circleDef = new b2CircleDef();
circleDef.radius = Math.random() * 15 + 10;
circleDef.density = 1.0;
circleDef.friction = 0.5;
circleDef.restitution = 0.2
bodyDef.AddShape(circleDef);
/*We have a Sprite object in the library called PhysCircle.*/
bodyDef.userData = new PhysCircle();
bodyDef.userData.width = circleDef.radius * 2;
bodyDef.userData.height = circleDef.radius * 2;
}
bodyDef.position.x = Math.random() * 400 + 120;
bodyDef.position.y = Math.random() * 100 + 50;
m_world.createBody(bodyDef);
addChild(bodyDef.userData);
}
很棒吧！的确是非常的简单。你应该了解的是Step()函数是只关心移动和旋转的，如果我们使用Sprites来定义的话，我们就需要手工的更新他们一下。我们只需要重写一下以前的updating函数：
public function updating(e:Event):void{
m_world.Step(m_timeStep, m_iterations);
// Go through body list and 更新 sprite positions/rotations
for (var bb:b2Body = m_world.m_bodyList; bb; bb = bb.m_next){
if (bb.m_userData is Sprite){
bb.m_userData.x = bb.m_position.x;
bb.m_userData.y = bb.m_position.y;
bb.m_userData.rotation = bb.m_rotation * (180/Math.PI);
}
}/*This is an extreemly clever way to do this, and I suggest you copy it exactly in your own projects.*/
}
到目前为止，我们把对象放到一个world中，它们之间可以相互碰撞和具有重力的作用。但是仍然有很多的东西需要讨论的，但是这里我只带领你到达"HelloWorld"。我们仍然可以去实现一些铁链，画论、齿轮和混合形状，摩擦旋转（像轮胎）等等。
一些相关的链接：
http://www.clickpopmedia.com/2008/03/17/physics-in-actionscript-3/
http://gphysics.com/
http://box2dflash.sourceforge.net/
http://www.box2d.org/

 

http://www.cnblogs.com/cwin5/archive/2009/03/22/1418841.html

http://space.flash8.net/space/?628770/viewspace-432180.html

http://space.flash8.net/space/?628770/viewspace-432191.html