VC下使用Macro （vbs）来实现标准注释的自动添加

在VC6.0中，Tools->Macro可以直接录制宏，实现源文件和函数的自动注释，编辑代码用vbs编写，代码如下：

'------------------------------------------------------------------------------
'FILE DESCRIPTION: 自动注释
'------------------------------------------------------------------------------

Sub FunctionDesc()
'DESCRIPTION: 函数注释
'Begin Recording
dim CurWin 
set CurWin = ActiveWindow
if CurWin is Nothing then exit sub

Dim FucNameBak 
ActiveDocument.Selection.SelectLine
FucNameBak = ActiveDocument.Selection
LTrim(FucNameBak)
RTrim(FucNameBak)

If FucNameBak = "" Then
   MsgBox "错误：请选中函数声明行！"
   Exit Sub
End If

Dim FuncName,FuncType,sTmp
Dim SpacePos,LeftPos,RightPos
SpacePos = Instr(1,FucNameBak," ",1)
LeftPos = Instr(1,FucNameBak,"(",1)
RightPos = Instr(1,FucNameBak,")",1)

If (LeftPos = 0) OR (RightPos=0) Then
   MsgBox "错误：函数体结构不完整，请检查代码！"
   Exit Sub
End If

If SpacePos = 0 Then
   FuncType = ""
   FuncName = Mid(FucNameBak,1,LeftPos-1)
Else
   FuncType = Mid(FucNameBak,1,SpacePos)
   FuncName = Mid(FucNameBak,SpacePos+1,LeftPos-SpacePos-1)
End If

Dim ParaArray
sTmp = Mid(FucNameBak,(LeftPos+1),(RightPos-LeftPos-1))
If sTmp <> "" Then
   ParaArray = Split(sTmp,",",-1,1)
End If

ActiveDocument.Selection.NewLine
ActiveDocument.Selection = "/**************************************************"
ActiveDocument.Selection.NewLine
ActiveDocument.Selection = "* 函数名称：" & FuncName
ActiveDocument.Selection.NewLine
ActiveDocument.Selection = "* 输入参数："

   '''''''''''''
If sTmp <> "" Then
	If UBound(ParaArray) < 0 Then
	   ActiveDocument.Selection = " 无 "
	Else
	   ActiveDocument.Selection = ( UBound(ParaArray) + 1 ) & "个参数 "
	   For i=0 To UBound(ParaArray)
		ActiveDocument.Selection.NewLine
		ActiveDocument.Selection = "*           参数" & (i+1) & ":" & RTrim(LTrim(ParaArray(i)))
	   Next
	End If
Else
	ActiveDocument.Selection = " 无 "	
End If
   '''''''''''''

ActiveDocument.Selection.NewLine
ActiveDocument.Selection = "* 输出参数：" & FuncType
ActiveDocument.Selection.NewLine
ActiveDocument.Selection = "* 函数功能：" 
ActiveDocument.Selection.NewLine
ActiveDocument.Selection = "* 创建作者：zyy" 
ActiveDocument.Selection.NewLine
ActiveDocument.Selection = "* 创建时间：" & Now()
ActiveDocument.Selection.NewLine
ActiveDocument.Selection = "**************************************************/"
ActiveDocument.Selection.NewLine
ActiveDocument.Selection = FucNameBak
'End Recording
End Sub

Sub FileDesc()
'DESCRIPTION: 文件注释
'Begin Recording
    ActiveDocument.Selection.StartOfDocument
    DefaultUserName = "zyy"
    Dim FileName
    FileName = ActiveDocument.Name
    ActiveDocument.Selection = "/******************************************************************" +_
                        vbLF + "* 文件名称：" + FileName +_
                        vbLF + "* 创建作者：" + DefaultUserName +_
                        vbLF + "* 创建时间：" + CStr(Now) +_
                        vbLF + "* 功能描述：" +_
                        vbLF + "* 修改记录：" +_
                        vbLF + "******************************************************************/"                       
    ActiveDocument.Selection.LineUp flase, 3
    ActiveDocument.Selection.EndOfLine
'End Recording
End Sub