将Comiket物的文件名格式统一化的脚本（F#版）

在前一篇日志，将Comiket物的文件名格式统一化的脚本，有这样的回复：

CloudiDust 写道

好想法……去用Groovy或者F#写一个……
其实我没有收Comiket物的习惯啊似乎……我真是没有娱乐的人啊……（望天）

既然Ruby的简单版和C#的版本都写了，写个F#版来对比一下也不错。
下面的程序逻辑基本上与前一篇的C#版类似，只是在如何抽取出文件名中的各部分的实现用了不同的划分方式：C#版的TryGetRenameName()方法更倾向于直接支持不同的pattern和format；F#版则是直接把pattern和format硬编码到parseFilename和getReformattedFilename函数里了。到底该怎么划分好我也不太肯定，不过在这么小的程序里划分方式好不好体现不出来，或许也不值得多想吧？

ReformatComiketFilenames.fsx

#light

open System
open System.IO
open System.Text.RegularExpressions

let parseFilename name =
  let result = Regex.Match(name, @"^\(([^)]+)\)\s*\(([^)]+)\)\s*\[([^\]]+)\]\s*(.+)$")
  let success = result.Success
  let comiketNum = result.Groups.Item(1).Value
  let contentType = result.Groups.Item(2).Value
  let circleName = result.Groups.Item(3).Value
  let itemName = result.Groups.Item(4).Value
  success, comiketNum, contentType, circleName, itemName

let getReformattedFilename name =
  let success, comiketNum, contentType, circleName, itemName = parseFilename name
  if success then
    sprintf "(%s)(%s)[%s] %s" comiketNum contentType circleName itemName
  else name

let reformatAndRenameDir (dirInfo : DirectoryInfo) =
  let name = dirInfo.Name
  let destName = getReformattedFilename name
  if name <> destName then
    printfn "%s" destName
    dirInfo.MoveTo(Path.Combine(dirInfo.Parent.FullName, destName))
    true
  else false

let reformatAndRenameFile (fileInfo : FileInfo) =
  let name = fileInfo.Name
  let destName = getReformattedFilename name
  if name <> destName then
    printfn "%s" destName
    fileInfo.MoveTo(Path.Combine(fileInfo.DirectoryName, destName))
    true
  else false

let getRootDir = fun () ->
#if COMPILED
  let args = Environment.GetCommandLineArgs ()
#else
  let args = fsi.CommandLineArgs
#endif
  let rootPath =
    match args with
    | [| _ |] -> new DirectoryInfo(Environment.CurrentDirectory);
    | _ -> new DirectoryInfo(args.[1])
  rootPath

let main = fun () ->
  let root = getRootDir ()
  Array.iter (fun dir -> (reformatAndRenameDir dir; ())) (root.GetDirectories())
  Array.iter (fun file -> (reformatAndRenameFile file; ())) (root.GetFiles())

main ()

F#的类型推导对.NET类型的支持还不是很好。let绑定的话，总是能从等号右手边的表达式判断出类型，这跟C#的var的实现其实是相似的。问题主要是函数的参数类型的推导。C#也有方法参数的类型推导问题（特别是在使用lambda表达式的时候），但C#的类型推导相对ML的弱很多。F#对内置类型能做比较好的推导，主要是因为内置类型的信息比较容易获取吧？.NET类型要用同样的推导方式太难实现了。
例如说看到

let succ x = x + 1

的时候，因为F#/OCaml默认+的的参数是int，所以很容易推导出x的类型是int，返回值类型也是int，于是succ的类型就是int -> int。
但如果是一个.NET类型：

let printName (fileInfo : FileInfo) =
  printfn "%s" fileInfo.Name

光凭fileInfo.Name这个属性访问，不足以提供fileInfo的类型信息。.NET类型不支持结构等价，结构相同的两个类在是不会被认为是同一个类型的：

class Foo { public string Name { get; set; } }
class Bar { public string Name { get; set; } }

这样的Foo与Bar虽然结构相同，但类型并不相等价。所以很明显，只有一个属性访问为条件，只能告诉F#的类型推导器“哪些类型肯定不满足条件”，却很难说明“哪个类型就是我们要找的类型”。F#的小组似乎在改进F#的类型推导器来改善对.NET类型的支持，不知道他们是怎么做的呢。

话说上面的代码里有这么一小段：

Array.iter (fun dir -> (reformatAndRenameDir dir; ())) (root.GetDirectories())

这里的括号其实挺无奈的……
我本来是想reformatAndRename*这两个函数应该返回些什么值，假如调用方想知道到底有没有做重命名，应该有办法知道。但最后我调用这两个函数的时候没有用到它们的返回值。Array.iter（和List.iter等）函数却对此不高兴了，非要第一个参数返回unit类型而不能是其它类型。所以这里的匿名函数只能写成(fun dir -> (reformatAndRenameDir dir; ()))了。写成这样能正确运行，不过F#的解释器会扔出一个警告说前一个子表达式应该返回unit类型而这里返回的是bool类型。嘛，警告就警告，不管了……

不过后来发觉括号多是我自己的问题而不是F#的问题……T T
这样写就好了：

Array.iter (fun dir -> reformatAndRenameDir dir |> ignore) (root.GetDirectories())

其中ignore是标准库里的函数，内容跟CloudiDust提到的fun x -> ()是一样的。

评论

4 楼 CloudiDust 2009-01-08  

话说暂时也没想到更好的方法……这个不单和语言的风格有关，和API的风格也是有关系的吧。

3 楼 RednaxelaFX 2009-01-08  

CloudiDust 写道

那个警告可以用一个“只进不出”的函数处理掉……

是可以用pipeline operator消掉，但挺没意义的……反正我知道这里我就是要忽略掉那个值，就让它警告呗。这种地方我没洁癖 =v=

hmm，要是在reformatAndRenameDir里再调用reformatAndRename*的话就是要实现递归的重命名了，不过我原本就只想重命名一层而已，所以没这么写。

.NET把Directory和File分隔开有时候很方便，但这里用起来就很罗嗦（可恶啊……
Ruby里明明一句File.rename就大功告成了 T T

还有什么更简洁的方式来实现这个功能么，用F#的话？
照我这么写那是挺overkill的……

2 楼 CloudiDust 2009-01-08  

……晕~把File和Directory写混了……

话说.Net里FileInfo和DirectoryInfo有这么多共同的方法为什么没有提升到基类里去……

1 楼 CloudiDust 2009-01-08  

谢谢。 xD

那个警告可以用一个“只进不出”的函数处理掉……（Haskell不是老干这种事情么 = =+）

Array.iter (fun dir -> (reformatAndRenameDir dir |> (fun x -> ())))(root.GetDirectories())

 

另外似乎在reformatAndRenameDir函数里面返回前应该调用一下：

reformatAndRenameFile (dirInfo.getDirectories())

用F#确实有些overkill的感觉……