根据物料特性获得物料号

 FORM frm_search_objects .

  TRANSLATE p_concat TO UPPER CASE. " contril category  Upper case
  TRANSLATE p_matcat TO UPPER CASE. " material category  Upper case

** Local data declaration.
  DATA: ls_klah     TYPE klah.    "Class Header Data.
  DATA: lt_criteria LIKE comw OCCURS 0 WITH HEADER LINE."Charac/Values.
  DATA: lt_atinn    LIKE clsel_r_atinn OCCURS 0 WITH HEADER LINE.
  DATA: lt_api_char LIKE api_char OCCURS 0 WITH HEADER LINE.
  DATA: lt_comw     LIKE comw OCCURS 0 WITH HEADER LINE.
  DATA: lv_class   LIKE clselinput-class VALUE 'N_QA_CLASS', "Class NO.
        lv_klart   LIKE klah-klart VALUE '001'.         "Class Type.

  DATA: lt_objects LIKE clsel_search_objects OCCURS 0 WITH HEADER LINE.
  DATA: lt_matvalues LIKE ausp OCCURS 0 WITH HEADER LINE.
  "Charac Values.

  FIELD-SYMBOLS: <fs_matvalues> LIKE LINE OF lt_matvalues,
                 <fs_objects>   LIKE LINE OF lt_objects.

  DATA: BEGIN OF ls_class,
        atnam  LIKE cabn-atnam,  "Internal characteristic.
        atbez  LIKE cabnt-atbez, "Characteristic description.
        atwrt  LIKE cawn-atwrt,  "Characteristic Value.
     END OF ls_class,
     lt_class LIKE TABLE OF ls_class.

  DATA: ls_features LIKE klvmera,
       lt_features  LIKE TABLE OF klvmera,
       ls_values   LIKE api_vali,
       lt_values    LIKE TABLE OF api_vali.
** Check that Class Exists and is Valid.
  CALL FUNCTION 'CLMA_CLASS_EXIST'
    EXPORTING
      class            = lv_class
      classtype        = lv_klart
      date             = sy-datum
      description_only = space
      language         = sy-langu
      mode             = 'S'
    IMPORTING
      xklah            = ls_klah
    EXCEPTIONS
      no_valid_sign    = 1
      OTHERS           = 2.
  ls_class-atnam = 'N_TECH_CONTROL'.
  ls_class-atwrt = p_concat.
  APPEND ls_class TO lt_class.

  ls_class-atnam = 'N_MATERIAL_CAT'.
  ls_class-atwrt = p_matcat.
  APPEND ls_class TO lt_class.
* Dynamic database set up for class entered.
  CALL FUNCTION 'CTMS_CLASS_DDB'
    EXPORTING
      class         = lv_class
      classtype     = lv_klart
      mode          = 'S'
      language      = sy-langu
      key_date      = sy-datum
      i_add_on_char = 'X'
      i_tabs_active = 'X'
    EXCEPTIONS
      OTHERS        = 0.

  CALL FUNCTION 'CTMS_DDB_CLOSE'
    TABLES
      exp_selection = lt_comw
    EXCEPTIONS
      OTHERS        = 0.

  CALL FUNCTION 'CLME_FEATURE_ATTR_OF_CLASS_ALL'
    EXPORTING
      class             = lv_class
      classtype         = lv_klart
      language          = sy-langu
      key_date          = sy-datum
      with_values       = 'X'
      i_sorted_by_class = 'X'
    TABLES
      tfeatures         = lt_features
      tvalues           = lt_values
    EXCEPTIONS
      class_not_found   = 1
      no_authority      = 2
      OTHERS            = 3.
** Select criteria of characteristic values.
  LOOP AT lt_class INTO ls_class WHERE atwrt NE space.
    READ TABLE lt_values INTO ls_values
                         WITH KEY atnam = ls_class-atnam
                                  atwrt = ls_class-atwrt.
    IF sy-subrc = 0.
      READ TABLE lt_comw WITH KEY atinn = ls_values-atinn.
      IF sy-subrc = 0.
        MOVE-CORRESPONDING lt_comw TO lt_criteria.
        lt_criteria-atwrt = ls_class-atwrt.
        lt_criteria-atzhl = ls_values-atzhl.
        lt_criteria-atflv = ls_values-atflv.
        lt_criteria-atcod = ls_values-atcod.
        lt_criteria-atflb = ls_values-atflb.
        lt_criteria-slflb = ls_values-atflb.
        IF ls_values-atcod = '1'.
          lt_criteria-slcod = '1'.
        ELSE.
          lt_criteria-slcod = '2'.
        ENDIF.
        APPEND lt_criteria TO lt_criteria[].
      ENDIF.
** Append Internal Characteristic Number.
      lt_atinn-sign = 'I'.
      lt_atinn-option = 'EQ'.
      lt_atinn-low    = ls_values-atinn.
      APPEND: lt_atinn.
      CLEAR: lt_criteria, ls_values, ls_class, lt_atinn.
    ENDIF.
  ENDLOOP.
*** Search material according to the characteristic values.
  IF lt_criteria[] IS NOT INITIAL or lt_atinn[] is NOT INITIAL.
    CALL FUNCTION 'CLSC_SEARCH_OBJECTS'
      EXPORTING
       i_classtype                    = lv_klart
       i_top_class_struc              = ls_klah
       i_keydate                      = sy-datum
       i_language                     = sy-langu
*       I_MAFID                        = 'O'
*       I_STATUS_FREE                  = 'X'
*       I_CTMS_DDB_LOADED              = 'X'
      TABLES
*       I_R_SUBCLASSES_TAB             =
*       I_R_OBJECTTYPES_TAB            =
       i_selection_criteria_tab       = lt_criteria[]
       i_r_characteristics_tab        = lt_atinn[]
       i_e_objects_tab                = lt_objects
       i_e_values_tab                 = lt_matvalues
     EXCEPTIONS
       no_objects_found               = 1
       inconsistent_parameters        = 2
       no_authority_classtype         = 3
       no_valid_classes               = 4
       internal_error                 = 5
       OTHERS                         = 6
              .
*    IF sy-subrc <> 0.
*      MESSAGE ID sy-msgid TYPE 'I' NUMBER sy-msgno
*              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
*    ENDIF.

** Get material number according to the characteristic values.
    IF lt_objects[] IS NOT INITIAL.
      LOOP AT lt_objects ASSIGNING <fs_objects>.
        gs_mat-matnr = <fs_objects>-object(18).
        APPEND gs_mat TO gt_mat.
        CLEAR: gs_mat.
      ENDLOOP.
    ELSE.
      LOOP AT lt_matvalues ASSIGNING <fs_matvalues>.
        gs_mat-matnr = <fs_matvalues>-objek(18).
        APPEND gs_mat TO gt_mat.
        CLEAR: gs_mat.
      ENDLOOP.
    ENDIF.
  ENDIF.
  IF gt_mat IS INITIAL.
    MESSAGE ' no data match this control category and Material category'
    TYPE 'I'.
    EXIT.
  ENDIF.
  SORT gt_mat BY matnr.
ENDFORM.                    " frm_search_objects

 

 

 

与特性值有关的表  ausp  cabn  也可以直接从表中查找