关于flex的Object类和Dictionary类

建议多用Dictionary , 最好是取代object (object 不会被编辑器检测) ,

下面是网上的关于Dictionary

AS3中的Dictionary类（flash.utils.Dictionary）是一个新的AS类。Dictionary类和Object唯一的区别在于：Dictionary对象可以使用非字符串作为键值对的键。例如：

var obj:Object = new Object();
obj["name"] = 1; // 键是字符串"name"
obj[1] = 2; // 键是1 (被转换成字符串"1")
obj[new Object()] = 3; // 键是new Object()，被转传成字符串"[object Object]"
for (var prop:String in obj) {
     trace(prop); // 输出：[object Object], 1, name
     trace(obj[prop]); // 输出：3, 2, 1
}

也就是说，无论用什么类型的变量作为键，都将被转换成字符串。同时，如果你使用了不同的对象作为键，都会北转换成字符串"[object Object]"作为键，因此而指向了同一个数据。例如：

ActionScript Code:   
var a:Object = new Object();   
var b:Object = new Object();   
var obj:Object = new Object();   
obj[a] = 1; // obj["[object Object]"] = 1;   
obj[b] = 2; // obj["[object Object]"] = 2;   
for (var prop:String in obj) {   
     trace(prop); // traces: [object Object]   
     trace(obj[prop]); // traces: 2   
}

Dictionary类将没有这个限制，你可以将键设置成任何一种数据类型。例如：

import flash.utils.Dictionary;
var a:Object = new Object();
var b:Object = new Object();
var dict:Dictionary = new Dictionary();
dict[a] = 1; // dict[a] = 1;
dict[b] = 2; // dict[b] = 2;
for (var prop:* in dict) {
     trace(prop); // traces: [object Object], [object Object]
     trace(dict[prop]); // traces: 1, 2
}

虽然在trace的时候，输出的还是[object Object]，但是这个结果是对象的toString的结果。在Dictionary对象中，代表的是不同的对象引用。

在Directionary类的构造函数中传入true
var dict:Dictionary = new Dictionary(true); // use weak references as keys
var obj:Object = new Object();
dict[obj] = true;
delete obj;

虽然dict中有引用到obj，但并不是一个有效引用，所以obj仍然会被垃圾回收