oracle发送邮件

CREATE OR REPLACE PACKAGE "PKG_SEND_EMS_MAIL" IS

  procedure p_splite_str(p_str varchar2, p_splite_flag int default 1);
  procedure write_data(p_conn   in out nocopy utl_smtp.connection,
                       p_name   in varchar2,
                       p_value  in varchar2,
                       p_splite varchar2 default ':',
                       p_crlf   varchar2 default utl_tcp.crlf);
  procedure end_boundary(conn in out nocopy utl_smtp.connection,
                         last in boolean default false);
  procedure p_email(p_sendoraddress2   varchar2, --发送地址
                    p_receiveraddress2 varchar2, --接受地址
                    p_receiver         varchar2, --收件人信息
                    p_sub              varchar2, --邮件标题
                    p_txt              varchar2 --邮件内容
                    );
  procedure send_mail(p_receiver         varchar2, --收件人信息
                    p_sub              varchar2, --p_sub为邮件标题
                    p_txt              varchar2 --p_txt为邮件内容
                    );
END PKG_SEND_EMS_MAIL;
/
CREATE OR REPLACE PACKAGE BODY "PKG_SEND_EMS_MAIL" IS

  p_user          varchar2(30) := '';
  p_pass          varchar2(30) := '';
  p_sendor        varchar2(50) := '[e-mail]';
  p_server        varchar2(20) := '';
  p_port          number := 25;
  p_need_smtp     number := 0;
  p_subject       varchar2(30000);
  l_crlf          varchar2(2) := utl_tcp.crlf;
  l_sendoraddress varchar2(4000);
  l_splite        varchar2(10) := '++';
  boundary            constant varchar2(256) := '-----BYSUK';
  first_boundary      constant varchar2(256) := '--' || boundary || l_crlf;
  last_boundary       constant varchar2(256) := '--' || boundary || '--' ||
                                                l_crlf;
  multipart_mime_type constant varchar2(256) := 'multipart/mixed; boundary="' ||
                                                boundary || '"';
  type address_list is table of varchar2(100) index by binary_integer;
  my_address_list address_list;

  procedure p_splite_str(p_str varchar2, p_splite_flag int default 1) is
    l_addr varchar2(254) := '';
    l_len  int;
    l_str  varchar2(4000);
    j      int := 0; --表示邮件地址或者附件的个数
  begin
    /*处理接收邮件地址列表，包括去空格、将;转换为,等*/
    l_str := trim(rtrim(replace(replace(p_str, ';', ','), ' ', ''), ','));
    l_len := length(l_str);
    for i in 1 .. l_len loop
      if substr(l_str, i, 1) <> ',' then
        l_addr := l_addr || substr(l_str, i, 1);
      else
        j := j + 1;
        if p_splite_flag = 1 then
          --表示处理邮件地址
          --前后需要加上'<>'，否则很多邮箱将不能发送邮件
          l_addr := '<' || l_addr || '>';
          --调用邮件发送过程
          my_address_list(j) := l_addr;
        end if;
        l_addr := '';
      end if;
      if i = l_len then
        j := j + 1;
        if p_splite_flag = 1 then
          --调用邮件发送过程
          l_addr := '<' || l_addr || '>';
          my_address_list(j) := l_addr;
        end if;
      end if;
    end loop;
  end;

  procedure write_data(p_conn   in out nocopy utl_smtp.connection,
                       p_name   in varchar2,
                       p_value  in varchar2,
                       p_splite varchar2 default ':',
                       p_crlf   varchar2 default utl_tcp.crlf) is
  begin
    /* utl_raw.cast_to_raw 对解决中文乱码问题很重要*/
    utl_smtp.write_raw_data(p_conn,
                            utl_raw.cast_to_raw(convert(p_name || p_splite ||
                                                        p_value || p_crlf,
                                                        'ZHS16CGB231280')));
  end;

  procedure end_boundary(conn in out nocopy utl_smtp.connection,
                         last in boolean default false) is
  begin
    utl_smtp.write_data(conn, utl_tcp.crlf);
    if (last) then
      utl_smtp.write_data(conn, last_boundary);
    end if;
  end;

  procedure p_email(p_sendoraddress2   varchar2, --发送地址
                    p_receiveraddress2 varchar2, --接受地址
                    p_receiver         varchar2, --收件人信息
                    p_sub              varchar2, --p_sub为邮件标题
                    p_txt              varchar2 --p_txt为邮件内容
                    ) is
    l_conn utl_smtp.connection; --定义连接
  begin
    /*初始化邮件服务器信息，连接邮件服务器*/
    l_conn := utl_smtp.open_connection(p_server, p_port);
    utl_smtp.helo(l_conn, p_server);
    /* smtp服务器登录校验 */
    if p_need_smtp = 1 then
      utl_smtp.command(l_conn, 'AUTH LOGIN', '');
      utl_smtp.command(l_conn,
                       utl_raw.cast_to_varchar2(utl_encode.base64_encode(utl_raw.cast_to_raw(p_user))));
      utl_smtp.command(l_conn,
                       utl_raw.cast_to_varchar2(utl_encode.base64_encode(utl_raw.cast_to_raw(p_pass))));
    end if;

    /*设置发送地址和接收地址*/
    utl_smtp.mail(l_conn, p_sendoraddress2);
    utl_smtp.rcpt(l_conn, p_receiveraddress2);

    /*设置邮件头*/
    utl_smtp.open_data(l_conn);
    /*设置日期*/
    --write_data(l_conn, 'Date', to_char(sysdate-1/3, 'dd Mon yy hh24:mi:ss'));
    /*设置发送人*/
    write_data(l_conn, 'From', p_sendor);
    /*设置接收人*/
    write_data(l_conn, 'To', p_receiver);
    /*设置邮件主题*/
    select replace('=?GB2312?B?' ||
                   utl_raw.cast_to_varchar2(utl_encode.base64_encode(rawtohex(p_sub))) || '?=',
                   utl_tcp.crlf,
                   '')
      into p_subject
      from dual;
    write_data(l_conn, 'Subject', p_subject);

    write_data(l_conn, 'Content-Type', multipart_mime_type);
    utl_smtp.write_data(l_conn, utl_tcp.crlf);
    utl_smtp.write_data(l_conn, first_boundary);
    write_data(l_conn, 'Content-Type', 'text/html;charset=gb2312');
    --单独空一行，否则，正文内容不显示
    utl_smtp.write_data(l_conn, utl_tcp.crlf);
    /* 设置邮件正文
      把分隔符还原成chr(10)。这主要是为了shell中调用该过程，如果有多行,则先把多行的内容合并成一行，并用 l_splite分隔
      然后用 l_crlf替换chr(10)。这一步是必须的，否则将不能发送邮件正文有多行的邮件
    */
    write_data(l_conn,
               '',
               replace(replace(p_txt, l_splite, chr(10)), chr(10), l_crlf),
               '',
               '');
    end_boundary(l_conn);
    /*关闭数据写入*/
    utl_smtp.close_data(l_conn);
    /*关闭连接*/
    utl_smtp.quit(l_conn);

  end;

  procedure send_mail(p_receiver         varchar2, --收件人信息
                    p_sub              varchar2, --p_sub为邮件标题
                    p_txt              varchar2 --p_txt为邮件内容
                    ) is
   v_error     varchar2(100);
    error_msg  varchar2(200);

    t_txt long(32767);
  begin
    p_server   := '10.0.64.113';

    /*begin
      select c_ip_address
        into p_server
        from tab_hardware_info a
       where a.c_description = '邮件服务器地址';

    exception
      when others then
        error_msg := '获取邮件服务器地址错误-';
        Raise_Application_Error('-20008', error_msg);
    end;*/

    --邮件收件人

    --p_receiver:='[e-mail]';
    if p_receiver is not null then
      --p_sub := 'JOB执行监控邮件';
      --p_txt := to_char(sysdate, 'YYYYMMDD') || '(JOB运行监控如下,如有异常,请及时处理)' ||
      --         '<br>' || '<br>';
      --获取ＪＯＢ监控信息
      t_txt:='';
      t_txt           := p_txt || t_txt;
      l_sendoraddress := '<' || p_sendor || '>';
      p_splite_str(p_receiver);
      for k in 1 .. my_address_list.count loop
        p_email(l_sendoraddress,
                my_address_list(k),
                p_receiver,
                p_sub,
                trim(t_txt));
      end loop;
    end if;

     exception
    when others then
      begin
        v_error := '发送邮件脚本程序异常。' || substr(sqlerrm, 1, 200);
        --pcis.pkg_finarp_common.insert_error_log('120', '12000', v_error);
      end;
  end;
  END PKG_SEND_EMS_MAIL;
/