QTP中对用户自定义环境变量的XML操作的几个函数

原文地址http://blog.csdn.net/tulituqi/article/details/5441121

大家可能都知道怎么在一个Test里的多个action之间传递参数，可以用DataTable也可以用Parameter。
那么在多个Test之间如何传递参数呢，一般常用的有excel，这个方法应该比较普遍了。这里介绍一下我自己设计的方法。
就是用环境变量来传递参数，我们都知道有个Environment环境变量（在File-Test Setting下），其中有一个是user-define，用户自定义的变量，而且这里还可以使用调用外部文件的方式来使用。那么我的方法就是基于此。
这里面我自己写了4个函数，
addVar(filepath,varname,varvalue)  给指定地址的xml添加一个变量。
delVar(filepath,varname)  删除xml里的变量
GetVars(filepath)  获得xml里的所有变量，以dictionary对象返回
updateVar(filepath,varname,varvalue)  更新xml里的变量的值。
我自己写的函数都不是很完善，没有过多考虑异常处理，大部分还是以正常通过为主写的，希望大家见谅。
这里的XML文件是QTP支持的格式，具体格式大家可以自己先创建几个环境变量，然后导出到外部文件，再看看那个xml的结构就行了。
大体上是这样的结构：
<Environment>
<Variable>
  <Name>upload</Name>
  <Value>T:/TestData/产险测试组/自动化公共库/upload.gif</Value>
</Variable>
<Variable>
  <Name>newVar</Name>
  <Value>ssdfff</Value>
</Variable>
</Environment>

所以我写的代码只能用于QTP这个环境变量的xml文件，对于其他的xml很可能不支持了。

再谈谈具体的用法，我这里的Test每一个都是独立的案例，其内部可以再调用其他可重用的action，也就是之前大家常用的方式，而我写这些函数的用途是为了能让多个独立的案例串连起来执行，在QC中通过执行流依次调用。
首先，在Test里开头使用
Environment.LoadFromFile(Path)
这个方法来读取环境变量文件。
使用的时候只要知道变量名即可了，直接使用Environment("upload")就可以了。
如果这个案例最后有需要传递出去的参数，就可以用addVar的方法。
另外需要考虑的问题就是在使用环境变量前，xml文件里如果没有那个变量就会报错。这里需要慎重一些。

这样使用的好处，每一个案例都是独立的，方便传递参数，同时，如果提出一个新的概念就是Test重用。我在做的一个项目就完整的使用我这套设计，把很长的案例都细化分解成一个个独立的案例，我就是为了Test之间传递参数方便使用的这个方法。而且在使用中发现有很多关键环节的Test可以重用，这比action的重用范围大了一些。不过我这些案例并没有什么特殊的，本身也会用到action重用，比如登录退出。

关于Test重用的话题，改天我拿几个例子来说比较好。可惜手头没有QC环境，不然可以截图配合QC使用来详细说明。

[vb] view plaincopyprint?
filepath="C:/UserDedinedEnvironment.xml" 
 
Set dics = GetVars(filepath) 
 
addVar filepath,"tttt","aaaa" 
Set dics = GetVars(filepath) 
updateVar filepath,"tttt","55555555" 
Set dics = GetVars(filepath) 
delVar filepath,"tttt" 
Set dics = GetVars(filepath) 
xx=1 
 
Function GetVars(filepath)    '已完成 
    Set objxml= CreateObject("MSXML.DOMDocument") 
    objxml.load filepath 
    Set Environ = objxml.lastChild    '获得<Environment>节点 
    Set dic = CreateObject("Scripting.Dictionary") 
    allVar = Environ.childNodes.length    '获得<Environment>节点的子节点数量，即变量个数。 
     
    For i=0 To allVar-1 
        Set vars=Environ.childNodes.item(i)    '获得<Variable>节点 
        var_name=vars.childNodes.item(0).nodeTypedValue 
         
        var_value=vars.childNodes.item(1).nodeTypedValue 
         
        dic.Add var_name,var_value 
    Next 
    Set GetVars = dic    '返回dictionary的环境变量列表 
    Set dic = Nothing 
End Function 
 
 
Function addVar(filepath,varname,varvalue)    '已完成 
    Set objxml= CreateObject("MSXML.DOMDocument") 
    objxml.load filepath 
    Set Environ = objxml.lastChild    '获得<Environment>节点 
 
    Set dic = CreateObject("Scripting.Dictionary") 
    allVar = Environ.childNodes.length    '获得<Environment>节点的子节点数量，即变量个数。 
     
    For i=0 To allVar-1 
        Set vars=Environ.childNodes.item(i)    '获得<Variable>节点 
        var_name=vars.childNodes.item(0).nodeTypedValue 
        var_value=vars.childNodes.item(1).nodeTypedValue 
        dic.Add var_name,var_value 
    Next 
    If dic.Exists(varname) Then 
        updateVar filepath,varname,varvalue 
        Exit Function 
    End If 
     
    Set vars =Environ.childNodes.item(0) 
    Set newVar= vars.cloneNode(1)    '复制<Variable>节点 
    '修改子节点的值 
    newVar.childNodes.item(0).nodeTypedValue = varname 
    newVar.childNodes.item(1).nodeTypedValue = varvalue 
    '添加节点 
    Set newEnv= Environ.appendChild(newVar) 
    '保存xml 
    objxml.save filepath 
End Function 
 
 
Function updateVar(filepath,varname,varvalue)  '已完成 
    Set objxml= CreateObject("MSXML.DOMDocument") 
    objxml.load filepath 
    Set Environ = objxml.lastChild    '获得<Environment>节点 
    allVar = Environ.childNodes.length    '获得<Environment>节点的子节点数量，即变量个数。 
     
'   Set dic = CreateObject("Scripting.Dictionary") 
'   For i=0 To allVar-1 
'       Set vars=Environ.childNodes.item(i)    '获得<Variable>节点 
'       var_name=vars.childNodes.item(0).nodeTypedValue 
'       var_value=vars.childNodes.item(1).nodeTypedValue 
'       dic.Add var_name,var_value 
'   Next 
'   If Not dic.Exists(varname) Then 
'       addVar filepath,varname,varvalue 
'       Exit Function 
'   End If 
 
    For i=0 To allVar-1 
        Set vars=Environ.childNodes.item(i)    '获得<Variable>节点 
        var_name=vars.childNodes.item(0).nodeTypedValue 
        If var_name=varname Then 
            vars.childNodes.item(1).nodeTypedValue = varvalue    '更新变量值 
            Exit For 
        End If 
    Next 
 
    '保存xml 
    objxml.save filepath 
End Function 
 
 
Function delVar(filepath,varname)    '已完成 
    Set objxml= CreateObject("MSXML.DOMDocument") 
    objxml.load filepath 
    Set Environ = objxml.lastChild    '获得<Environment>节点 
     
    allVar = Environ.childNodes.length    '获得<Environment>节点的子节点数量，即变量个数。 
    If allVar=1 Then 
        Exit Function 
    End If 
    For i=0 To allVar-1 
        Set vars=Environ.childNodes.item(i)    '获得<Variable>节点 
        var_name=vars.childNodes.item(0).nodeTypedValue 
        If var_name=varname Then 
            Environ.removeChild(vars)     '删除节点 
            Exit For 
        End If 
    Next 
 
    '保存xml 
    objxml.save filepath 
End Function