学习JavaFX脚本语言----3,4

Lesson 3: Using Objects

目录

- 什么是对象？
- 声明一个对象
- 对象结构
- 执行实例方法

-什么是对象？

什么是对象？对象是软件里面互不关联的部分，对象具有状态和行为！简言之：

对象的变量表示对象的状态。
对象的方法表示对象的行为。.
理论上，对象能模拟任何东西，从GUI组件(按钮，多选框，标签)到不可见的抽象的东西(温度，金融，产品注册信息等)

Note:想了解更多，请看Java教程里的相应教程。


-声明一个对象

在JavaFX脚本语言里面，对象是由object literal创建的。

Address {
     street: "1 Main Street";
     city: "Santa Clara";
     state: "CA";
     zip: "95050";
}

我们创建了一个Address对象，给假象的地址簿应用程序使用。下载Address.zip解压缩类文件和AddressBook.fx

Note:Address.class文件(Address.class和Address$Intf.class)包含了你创建Address对象的重要信息，供编译器使用。如果你想知道这些文件是从哪里来的，你可以先创建Address类的定义文件(叫Address.fx的文件)，然后编译它，就会生成Address.class文件。JavaFX脚本语言和Java语言提供了很多预编译的class文件供你在程序里面使用。这使得你可以完成不同领域的任务，包括创建有震撼视觉效果的GUI程序。我们会在此教程的最后告诉你怎么创建自己的类，在Writing Your Own Classes章节！这里，你只需要下载需要的类文件就可以了。

现在，编译脚本：javafxc AddressBoox.fx，如果没有任何的输出，则说明编译成功。

Note:技术术语，这里的变量应该叫做实例变量。你可以把实例变量想象成每个对象都会有的内建的属性。事实上，“属性”这个词是在以前版本里面使用的概念。在OOP的世界里面"instance"和"object"是同义的！


-对象结构

对象结构很容易学习和使用！第一个单词（Address）指出了你要创建的对象类型。两个大括号定义了对象的内容。对象里的每个实例变量都给了一个初始值。(street, city, state, zip)

多个对象可以在一起创建：

Address {
     street: "1 Main Street";
     city: "Santa Clara";
     state: "CA";
     zip: "95050";
}

Address {
     street: "200 Pine Street";
     city: "San Francisco";
     state: "CA";
     zip: "94101";
}

Note:当定义一个object literal，实例变量可以以空格，逗号和分号隔开！下面的定义也是正确的：

Address {
     street: "1 Main Street"
     city: "Santa Clara"
     state: "CA"
     zip: "95050"
}

Address {
     street: "200 Pine Street",
     city: "San Francisco",
     state: "CA",
     zip: "94101",
}

教程里面将使用分号来作为分隔符。当定义一个方法的时候，分号是必须的。
你也可以将一个刚创建的对象和一个之前创建的对象关联。

def addressOne = Address {
     street: "1 Main Street";
     city: "Santa Clara";
     state: "CA";
     zip: "95050";
}

def addressTwo = Address {
     street: "200 Pine Street";
     city: "San Francisco";
     state: "CA";
     zip: "94101";
}
 
或者将一个对象放置到另一个对象里面！

def customer = Customer {
     firstName: "John";
     lastName: "Doe";
     phoneNum: "[phone]";
     address: Address {
          street: "1 Main Street";
          city: "Santa Clara";
          state: "CA";
          zip: "95050";
     }
}

在最新版本的例子里面，Customer定义了几个新的变量。而里面的address变量持有了一个Address对象。这种格式很平常，看看程序怎么缩进的。通过缩进，Address的变量和Customer里面的变量能很容易的辨认出来！要编译这个例子，下载Customer.zip,解压缩到相同的目录，编译即可。


-执行实例方法

JavaFX提供高了很多行为为你提供便利！这些行为是通过对象的方法提供的。

你通过变量的名字（这里是customer），后面跟个"."，紧接着是方法名称，这样的形式来执行实例方法。

def customer = Customer {
     firstName: "John";
     lastName: "Doe";
     phoneNum: "[phone]"
     address: Address {
          street: "1 Main Street";
          city: "Santa Clara";
          state: "CA";
          zip: "95050";
     }
}

customer.printName();
customer.printPhoneNum();
customer.printAddress();

输出：

Name: John Doe
Phone: [phone]
Street: 1 Main Street
City: Santa Clara
State: CA
Zip: 95050

你现在可能想知道，这些方法是哪来的？我怎么知道一个对象里面包含那些变量和方法？如果你想使用一个类库，你需要API。API是一个格式良好的文档，列出了对象的变量和方法！这是唯一可以确定对象会提供什么方法的途径。在之后的教程里，在你要创建图形化程序的时候，你会学到如何的使用这个文档！

Lesson 4: Data Types
Contents

- String
- Number and Integer
- Boolean
- Duration
- Void
- Null

-String

你已经看过很多String的例子了，但是还是让我们来自习的看看它还具有那些特性。String的定义，可以用双引号，也可以用单引号！

var s1 = 'Hello';
var s2 = "Hello";

不论单引号还是双引号都必须是对称的：你能在双引号里面嵌入单引号，或者在单引号里面嵌入双引号。以单引号定义的String和双引号定义的String之间没有任何的区别！

你还能在String里面插入表达式，表达式以"{}"包围。

def name = 'Joe';
var s = "Hello {name}"; // s = 'Hello Joe'

在表达式里面还能够再嵌入String：

def answer = true;
var s = "The answer is {if (answer) "Yes" else "No"}"; // s = 'The answer is Yes'

在运行时，编译器会根据answer的值来使用"Yes"或者"No"自动的替换掉表达式。

要连接多个String，使用多个大括号即可。

def one = "This example ";
def two = "joins two strings.";
def three = "{one}{two}";      // join string one and string two
println(three);                // 'This example joins two strings.'

-Number and Integer

Number 和Integer 接收数字类型的值，而很多情况下，你让编译器自己去猜测是什么类型就可以了。

def numOne = 1.0; // compiler will infer Number 
def numTwo = 1;   // compiler will infer Integer

当然，你可以指定变量的类型：

def numOne : Number = 1.0;
def numTwo : Integer = 1;

两者的区别是Number是浮点型而Integer是整型。只有当你需要浮点型的时候才使用Number，否则建议使用Integer.

-Boolean

Boolean 有两个值：true 和 false。当需要设置程序的特定状态时，使用此变量类型。

var isAsleep = true; 

或者是一个条件表达式：

if (isAsleep) {
     wakeUp();
}

当()里面的值为true时，{}里面的代码将被执行。关于更多内容，请看Expressions lesson

-Duration

Duration 类型表示一系列的时间：

5ms; // 5 milliseconds
10s; // 10 seconds
30m; // 30 minutes
1h;  // 1 hour

Durations被解释为时间---比如，5m就是5分钟。时间在animation 里将被频繁的使用。（请参看Building GUI Applications with JavaFX里面的Creating Animated Objects章节）

-Void

Void是被用来说明一个方法没有返回值的。

function printMe() : Void {
     println("I don't return anything!");
}
 
下面是等价的，省略了返回值

function printMe() {
     println("I don't return anything!");
}
 

JavaFX里面的关键字Void，以大写V开头。如果你熟悉Java语言里面的void类型，请特别注意！

Note:在JavaFX里面，一切都是表达式。在第二个printMe里面返回值依然是Void，编译器能自动识别。在Expressions lesson你将会了解更多内容。

-Null

Null是一个特殊的值，表示一个变量没有一个正常值。Null不同于数字0或者空字符串，所以当Null和数字0或空字符串比较时，是不等的。

null关键字可以用来做比较，如下所示：

function checkArg(arg1: Address) {
     if(arg1 == null) {
          println("I received a null argument.");
     } else {
          println("The argument has a value.");
     }
}

这个方法接收一个参数，判断是否为null.

评论

1 楼 flyfan 2008-12-09  

学习了，现在等eclipse一个好的插件