papervision3d的第二的例子：得到一些默认值

做个例子看看pv3d的一些默认参数是什么，以及pv3d的坐标怎么样的。主要的方法，是采用trace()语句，以及改变一些参数对照效果。flash的效果是：一个球在中间瞎转，再让一个平面切着球也瞎转。

 

　令人欣喜的是pv3d用的并不是屏幕坐标系，而是采用现实坐标系，不用做那些复杂的坐标转换了。其他的测试值已经写在代码里了。

package {
	
     import flash.display.Sprite;
     import flash.events.Event;
     
     import org.papervision3d.materials.WireframeMaterial;
     import org.papervision3d.objects.DisplayObject3D;
     import org.papervision3d.objects.primitives.Plane;
     import org.papervision3d.objects.primitives.Sphere;
     import org.papervision3d.view.BasicView;
     
     [SWF(width="400", height="400", backgroundColor="0xFC5A0A",frameRate='40')]  
     
     public class Main extends Sprite   
     {                       
         private var basicView:BasicView;
         
         private var planeDisplayObj:DisplayObject3D;
         private var sphere:Sphere;
         private var planeFront:Plane,planeBack:Plane;
         
         private var materialForSphere:WireframeMaterial;
         private var materialForPlane:WireframeMaterial;
         
         private static const R:Number = 50; 
                 
         public function Main()  
         {  
             init();
             //添加侦听器
             addEventListener( Event.ENTER_FRAME , onEnterFrame);       
         }            
         private function init():void{                   
         	 basicView = new BasicView();
         	 addChild( basicView );
         	 //由于是采用的Sprite的addChild方法，所以采用的还是屏幕坐标系
         	 //BasicView是Sprite的子类，默认时它的位置是(0,0)
         	         	 
         	 //通过用trace输出可以看到，默认时zoom为2
         	 trace("the zoom value of camera is "+basicView.camera.zoom);         	 
         	 basicView.camera.zoom = 20;         
         	 //用trace输出可以看到，默认时camera处于位置坐标为(0,0,-1000)         	
         	 trace("the x of the camera is " + basicView.camera.x);
         	 trace("the y of the camera is " + basicView.camera.y);
         	 trace("the z of the camera is " + basicView.camera.z);
         	 
         	 //basicView.camera.z = 0 ; //可以调整z，有走远走近的效果
         	 
         	 //创建材质
         	 materialForPlane  = new WireframeMaterial(0x05234D);
         	 materialForSphere = new WireframeMaterial(0x05234D);
         	 //创建球体
         	 sphere = new Sphere(materialForSphere , R , 16, 12);         
         	 basicView.scene.addChild( sphere );    
         	 //pv3d中使用的坐标系是与高数课本中的坐标系是一样的
         	 //并没有采用屏幕坐标系，原点在正中点   
         	 //在没设置时新添加的组件坐标为(0,0,0)           
         	 //即球的重心处在原点上(不知道可不可以这样理解)	       
         	          	 
         	 planeDisplayObj = new DisplayObject3D();
         	 //创建平面   	 	          	         	          
         	 planeFront = new Plane( materialForPlane,140,140,12,12);
         	 planeDisplayObj.addChild(  planeFront );        
         	 planeBack = new Plane( materialForPlane,140,140,12,12);
         	 planeBack.rotationY = 180;//要将背面旋转一个180度，这样背面才能被显示出来
         	 planeDisplayObj.addChild(  planeBack );         
         	 basicView.scene.addChild( planeDisplayObj );
         	          	 
         	 //trace得到默认时各rotation为0,rotation采用的是角度，不是弧度
         	 trace("the rotationX of the plane is " + planeDisplayObj.rotationX);
         	 trace("the rotationY of the plane is " + planeDisplayObj.rotationY);
         	 trace("the rotationZ of the plane is " + planeDisplayObj.rotationZ);           	         	      	  
         	 //显示出来
         	 basicView.singleRender(); 	       	   	
         }  
         
         internal function onEnterFrame(event:Event):void{         	
         	sphere.rotationY += 5;  
         	sphere.rotationX += 5;    //旋转球
         	planeDisplayObj.rotationY  += 5; //平面y轴旋转 
         	//做成平面切着球旋转的效果，所以除了设置旋转角度，还要设置新的位置
         	var rotation:Number = planeDisplayObj.rotationY*3.1415/180;         	
         	planeDisplayObj.x = -  R * Math.sin(rotation);
         	planeDisplayObj.z = -  R - Math.cos(rotation);       	
         	basicView.singleRender(); 	    
         }
           
     }  
}