Flex4 多语言

Flex在3和4中都有Localization的支持，包括使用Resource Modules。不过我并不打算使用该方法。

原因有二

 

1·Resource Modules过大：

 

使用Resource Modules是一种很好的设计模式，其意图是希望在运行状态中将资源从外部加载进来，以达到

减少垃圾文件及动态更换语言的目的。不过在最新Flex4版本中，这个想法还是没有很好的体现出来。

我编写了一个1K大小的lang.properties但是导出的Resource Modules确有18K（见原帖）。

这样完全没有达到使用Resource Modules的目的，至少对于多语言这方面是没有什么意义。

 

2·使用ResourceManager无法替换文字中的转义符：

 

文字中出现转义符的在很多程序设计中都有需要，由其在游戏中经常会需要显示如下的信息

"Congratulate you have found #ITEM_NAME#" ; "Hello #USER_NAME# ,nice to meet you"

无论使用@Resource 还是运行期间使用resourceManager.getString(**,**)，

ResourceManager都无法胜任该工作。

 

因此，我自己设计了一套多语言结构,拿出来和大家探讨一下。如果有什么想法欢迎留言

 

Main:

MXML语言:

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
               xmlns:s="library://ns.adobe.com/flex/spark"
               xmlns:mx="library://ns.adobe.com/flex/halo"
               minWidth="1024"
               minHeight="768"
               width="348"
               height="314"
               initialize="onInit()">

    <fx:Script>
        <![CDATA[
            import fl.video.INCManager;
            import mx.rpc.events.XMLLoadEvent;
            import mx.rpc.soap.LoadEvent;
            import copyengine.common.lang.LanguageHandle;
            import mx.managers.PopUpManager;
            private var xmlLoader1:URLLoader;
            private var xmlLoader2:URLLoader;
            private var loaderCounter:int;

            private function onInit():void
            {
                loaderCounter=0;
                xmlLoader1=new URLLoader();
                xmlLoader1.dataFormat=URLLoaderDataFormat.BINARY;
                xmlLoader1.load(new URLRequest("../res/xml/lang_en.xml"));
                xmlLoader1.addEventListener(Event.COMPLETE, onLoadComplate);

                xmlLoader2=new URLLoader();
                xmlLoader2.dataFormat=URLLoaderDataFormat.BINARY;
                xmlLoader2.load(new URLRequest("../res/xml/lang_cn.xml"));
                xmlLoader2.addEventListener(Event.COMPLETE, onLoadComplate);
            }

            private function onLoadComplate(e:Event):void
            {
                LanguageHandle.instance.addLanguage(new XML(e.target.data));
                loaderCounter++;
                if (loaderCounter == 2)
                {
                    LanguageHandle.instance.init("EN");
                    PopUpManager.createPopUp(this, Panel1);
                }
            }
        ]]>
    </fx:Script>
</s:Application>

 

Main 函数主要目的是初始化LanguageHandle，由于仅是做个Demo演示 所以没有写的那么复杂，代码看起来比较2....

 

LanguageHandle:

ActionScript 3语言:

package copyengine.common.lang
{
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.utils.Dictionary;

    public class LanguageHandle extends EventDispatcher
    {
        private static var _instance:LanguageHandle;

        public static function get instance():LanguageHandle
        {
            if (_instance == null)
            {
                _instance=new LanguageHandle();
            }
            return _instance;
        }

        private var allLanguageRes:Dictionary;
        private var currentLanguage:String;

        public function LanguageHandle()
        {
            allLanguageRes=new Dictionary();
        }

        public function init(_language:String):void
        {
            currentLanguage=_language;
        }

        public function addLanguage(_langXml:XML):void
        {
            currentLanguage=_langXml.@val;
            var currentRes:Vector.<LanguageFile>=new Vector.<LanguageFile>();
            allLanguageRes[currentLanguage]=currentRes;
            for each (var node:XML in _langXml.text)
            {
                var languageFile:LanguageFile=new LanguageFile;
                languageFile.textID=node.@id;
                languageFile.textValue=node.@val;
                currentRes.push(languageFile);
            }
        }

        [Bindable(event="CopyEngine_LanguageChange")]
        public function getText(_textID:String):String
        {
            var currentRes:Vector.<LanguageFile>=allLanguageRes[currentLanguage];
            for each (var langugeFile:LanguageFile in currentRes)
            {
                if (langugeFile.textID == _textID)
                {
                    return langugeFile.textValue;
                }
            }
            return null;
        }

        public function changeLanguage(_language:String):void
        {
            currentLanguage=_language;
            dispatchEvent(new Event("CopyEngine_LanguageChange"));
        }

    }
}

 

主要注意

 

  [Bindable(event="CopyEngine_LanguageChange")]
  public function getText(_textID:String):String]{}

 

这个是对getText函数进行绑定，当有Event-->CopyEngine_LanguageChange产生时，该函数即Call，

在最下方，当更换语言时就会dispatch出该Event

 

测试类：

MXML语言:

<?xml version="1.0" encoding="utf-8"?>
<s:Panel xmlns:fx="http://ns.adobe.com/mxml/2009"
         xmlns:s="library://ns.adobe.com/flex/spark"
         xmlns:mx="library://ns.adobe.com/flex/halo"
         width="275"
         height="181">
    <fx:Script>
        <![CDATA[
            import copyengine.common.lang.LanguageHandle;
        ]]>
    </fx:Script>
    <s:Button x="148"
              y="79"
              label="{LanguageHandle.instance.getText('BUTTON_CANCEL')}"
              width="60"
              height="20"/>
    <s:Button x="51"
              y="79"
              label="{LanguageHandle.instance.getText('BUTTON_OK')}"
              width="59"
              height="22"/>
    <s:TextArea x="33"
                y="0"
                height="73"
                width="198"
                text="{LanguageHandle.instance.getText('PANEL1_INFO')}"/>
    <s:Button x="6"
              y="121"
              label="CN"
              click="LanguageHandle.instance.changeLanguage('CN')"/>
    <s:Button x="195"
              y="121"
              label="EN"
              click="LanguageHandle.instance.changeLanguage('EN')"/>
    <s:layout>
        <s:BasicLayout/>
    </s:layout>
</s:Panel>

 

由于仅仅是简单的Demo，所以就没有封装Rplace函数，不过原理都是一样。

 

最终演示