CREATE PROCEDURE [dbo].[sp_undecrypt]
(
@procedure SYSNAME = NULL ,
@revfl INT = 1
)
AS /**//*
王成辉翻译整理，转贴请注明出自微软BI开拓者www.windbi.com
调用形式为：
exec dbo.sp__windbi$decrypt @procedure,0
如果第二个参数使用1的话，会给出该存储过程的一些提示。
--版本4.0 修正存储过程过长解密出来是空白的问题
*/
SET NOCOUNT ON
IF @revfl = 1
BEGIN
PRINT '警告：该存储过程会删除并重建原始的存储过程。'
PRINT ' 在运行该存储过程之前确保你的数据库有一个备份。'
PRINT ' 该存储过程通常应该运行在产品环境的一个备份的非产品环境下。'
PRINT ' 为了运行这个存储过程，将参数@refl的值更改为0。'
RETURN 0
END
DECLARE @intProcSpace BIGINT ,
@t BIGINT ,
@maxColID SMALLINT ,
@procNameLength INT
SELECT @maxColID = MAX(subobjid)
FROM sys.sysobjvalues
WHERE objid = OBJECT_ID(@procedure)
--select @maxColID as 'Rows in sys.sysobjvalues'
SELECT @procNameLength = DATALENGTH(@procedure) + 29
DECLARE @real_01 NVARCHAR(MAX)
DECLARE @fake_01 NVARCHAR(MAX)
DECLARE @fake_encrypt_01 NVARCHAR(MAX)
DECLARE @real_decrypt_01 NVARCHAR(MAX) ,
@real_decrypt_01a NVARCHAR(MAX)
DECLARE @objtype VARCHAR(2) ,
@ParentName NVARCHAR(MAX)
SELECT @real_decrypt_01a = ''
--提取对象的类型如是存储过程还是函数，如果是触发器，还要得到其父对象的名称
SELECT @objtype = type ,
@parentname = OBJECT_NAME(parent_object_id)
FROM sys.objects
WHERE [object_id] = OBJECT_ID(@procedure)
-- 从sys.sysobjvalues里提出加密的imageval记录
SET @real_01 = ( SELECT TOP 1
imageval
FROM sys.sysobjvalues
WHERE objid = OBJECT_ID(@procedure)
AND valclass = 1
ORDER BY subobjid
)
--创建一个临时表
CREATE TABLE #output
(
[ident] [int] IDENTITY(1, 1)
NOT NULL ,
[real_decrypt] NVARCHAR(MAX)
)
--开始一个事务，稍后回滚
BEGIN TRAN
--更改原始的存储过程，用短横线替换
IF @objtype = 'P'
SET @fake_01 = 'ALTER PROCEDURE ' + @procedure
+ ' WITH ENCRYPTION AS select 1
/**//*' + REPLICATE(CAST('*' AS NVARCHAR(MAX)),
DATALENGTH(@real_01) / 2 - @procNameLength) + '*/'
ELSE
IF @objtype = 'FN'
SET @fake_01 = 'ALTER FUNCTION ' + @procedure
+ '() RETURNS INT WITH ENCRYPTION AS BEGIN RETURN 1
/**//*' + REPLICATE(CAST('*' AS NVARCHAR(MAX)),
DATALENGTH(@real_01) / 2 - @procNameLength) + '*/ END'
ELSE
IF @objtype = 'V'
SET @fake_01 = 'ALTER view ' + @procedure
+ ' WITH ENCRYPTION AS select 1 as col
/**//*' + REPLICATE(CAST('*' AS NVARCHAR(MAX)),
DATALENGTH(@real_01) / 2 - @procNameLength) + '*/'
ELSE
IF @objtype = 'TR'
SET @fake_01 = 'ALTER trigger ' + @procedure + ' ON '
+ @parentname
+ 'WITH ENCRYPTION AFTER INSERT AS RAISERROR (''N'',16,10)
/**//*' + REPLICATE(CAST('*' AS NVARCHAR(MAX)),
DATALENGTH(@real_01) / 2 - @procNameLength) + '*/'
EXECUTE (@fake_01)
--从sys.sysobjvalues里提出加密的假的
SET @fake_encrypt_01 = ( SELECT TOP 1
imageval
FROM sys.sysobjvalues
WHERE objid = OBJECT_ID(@procedure)
AND valclass = 1
ORDER BY subobjid
)
IF @objtype = 'P'
SET @fake_01 = 'Create PROCEDURE ' + @procedure
+ ' WITH ENCRYPTION AS select 1
/**//*' + REPLICATE(CAST('*' AS NVARCHAR(MAX)),
DATALENGTH(@real_01) / 2 - @procNameLength) + '*/'
ELSE
IF @objtype = 'FN'
SET @fake_01 = 'CREATE FUNCTION ' + @procedure
+ '() RETURNS INT WITH ENCRYPTION AS BEGIN RETURN 1
/**//*' + REPLICATE(CAST('*' AS NVARCHAR(MAX)),
DATALENGTH(@real_01) / 2 - @procNameLength) + '*/ END'
ELSE
IF @objtype = 'V'
SET @fake_01 = 'Create view ' + @procedure
+ ' WITH ENCRYPTION AS select 1 as col
/**//*' + REPLICATE(CAST('*' AS NVARCHAR(MAX)),
DATALENGTH(@real_01) / 2 - @procNameLength) + '*/'
ELSE
IF @objtype = 'TR'
SET @fake_01 = 'Create trigger ' + @procedure + ' ON '
+ @parentname
+ 'WITH ENCRYPTION AFTER INSERT AS RAISERROR (''N'',16,10)
/**//*' + REPLICATE(CAST('*' AS NVARCHAR(MAX)),
DATALENGTH(@real_01) / 2 - @procNameLength) + '*/'
--开始计数
SET @intProcSpace = 1
--使用字符填充临时变量
SET @real_decrypt_01 = REPLICATE(CAST('A' AS NVARCHAR(MAX)),
( DATALENGTH(@real_01) / 2 ))
--循环设置每一个变量，创建真正的变量
--每次一个字节
SET @intProcSpace = 1
--如有必要，遍历每个@real_xx变量并解密
WHILE @intProcSpace <= ( DATALENGTH(@real_01) / 2 )
BEGIN
--真的和假的和加密的假的进行异或处理
SET @real_decrypt_01 = STUFF(@real_decrypt_01, @intProcSpace, 1,
NCHAR(UNICODE(SUBSTRING(@real_01,
@intProcSpace, 1))
^ ( UNICODE(SUBSTRING(@fake_01,
@intProcSpace, 1))
^ UNICODE(SUBSTRING(@fake_encrypt_01,
@intProcSpace, 1)) )))
SET @intProcSpace = @intProcSpace + 1
END
--通过sp_helptext逻辑向表#output里插入变量
INSERT #output
( real_decrypt )
SELECT @real_decrypt_01
--select real_decrypt AS '#output chek' from #output --测试
-- -------------------------------------
--开始从sp_helptext提取
-- -------------------------------------
DECLARE @dbname SYSNAME ,
@BlankSpaceAdded INT ,
@BasePos INT ,
@CurrentPos INT ,
@TextLength INT ,
@LineId INT ,
@AddOnLen INT ,
@LFCR INT --回车换行的长度
,
@DefinedLength INT ,
@SyscomText NVARCHAR(MAX) ,
@Line NVARCHAR(255)
SELECT @DefinedLength = 255
SELECT @BlankSpaceAdded = 0 --跟踪行结束的空格。注意Len函数忽略了多余的空格
CREATE TABLE #CommentText
(
LineId INT ,
Text NVARCHAR(255) COLLATE database_default
)
--使用#output代替sys.sysobjvalues
DECLARE ms_crs_syscom CURSOR LOCAL
FOR
SELECT real_decrypt
FROM #output
ORDER BY ident FOR READ ONLY
--获取文本
SELECT @LFCR = 2
SELECT @LineId = 1
OPEN ms_crs_syscom
FETCH NEXT FROM ms_crs_syscom INTO @SyscomText
WHILE @@fetch_status >= 0
BEGIN
SELECT @BasePos = 1
SELECT @CurrentPos = 1
SELECT @TextLength = LEN(@SyscomText)
WHILE @CurrentPos != 0
BEGIN
--通过回车查找行的结束
SELECT @CurrentPos = CHARINDEX(CHAR(13) + CHAR(10),
@SyscomText, @BasePos)
--如果找到回车
IF @CurrentPos != 0
BEGIN
--如果@Lines的长度的新值比设置的大就插入@Lines目前的内容并继续
WHILE ( ISNULL(LEN(@Line), 0) + @BlankSpaceAdded
+ @CurrentPos - @BasePos + @LFCR ) > @DefinedLength
BEGIN
SELECT @AddOnLen = @DefinedLength
- ( ISNULL(LEN(@Line), 0)
+ @BlankSpaceAdded )
INSERT #CommentText
VALUES ( @LineId,
ISNULL(@Line, N'')
+ ISNULL(SUBSTRING(@SyscomText,
@BasePos,
@AddOnLen), N'') )
SELECT @Line = NULL ,
@LineId = @LineId + 1 ,
@BasePos = @BasePos + @AddOnLen ,
@BlankSpaceAdded = 0
END
SELECT @Line = ISNULL(@Line, N'')
+ ISNULL(SUBSTRING(@SyscomText, @BasePos,
@CurrentPos - @BasePos
+ @LFCR), N'')
SELECT @BasePos = @CurrentPos + 2
INSERT #CommentText
VALUES ( @LineId, @Line )
SELECT @LineId = @LineId + 1
SELECT @Line = NULL
END
ELSE
--如果回车没找到
BEGIN
IF @BasePos <= @TextLength
BEGIN
--如果@Lines长度的新值大于定义的长度
WHILE ( ISNULL(LEN(@Line), 0)
+ @BlankSpaceAdded + @TextLength
- @BasePos + 1 ) > @DefinedLength
BEGIN
SELECT @AddOnLen = @DefinedLength
- ( ISNULL(LEN(@Line), 0)
+ @BlankSpaceAdded )
INSERT #CommentText
VALUES ( @LineId,
ISNULL(@Line, N'')
+ ISNULL(SUBSTRING(@SyscomText,
@BasePos,
@AddOnLen), N'') )
SELECT @Line = NULL ,
@LineId = @LineId + 1 ,
@BasePos = @BasePos
+ @AddOnLen ,
@BlankSpaceAdded = 0
END
SELECT @Line = ISNULL(@Line, N'')
+ ISNULL(SUBSTRING(@SyscomText,
@BasePos,
@TextLength
- @BasePos + 1),
N'')
IF LEN(@Line) < @DefinedLength
AND CHARINDEX(' ', @SyscomText,
@TextLength + 1) > 0
BEGIN
SELECT @Line = @Line + ' ' ,
@BlankSpaceAdded = 1
END
END
END
END
FETCH NEXT FROM ms_crs_syscom INTO @SyscomText
END
IF @Line IS NOT NULL
INSERT #CommentText
VALUES ( @LineId, @Line )
SELECT Text
FROM #CommentText
ORDER BY LineId
CLOSE ms_crs_syscom
DEALLOCATE ms_crs_syscom
DROP TABLE #CommentText
-- -------------------------------------
--结束从sp_helptext提取
-- -------------------------------------
--删除用短横线创建的存储过程并重建原始的存储过程
ROLLBACK TRAN
DROP TABLE #output
分享到：
相关推荐
绿色版查看sql加密存储过程、视图等工具
查看sql加密存储过程
SQL 加密 SQL Server 中的加密是指通过使用密钥或密码对数据进行模糊处理的过程。加密不能替代其他的安全设置，而是作为数据库被破解或备份被窃取后的最后一道防线。通过加密，使得未被授权的人在没有密钥或密码的...
标题提到的“破解sql加密的存储过程”正是针对这种需求的一种解决方案。 首先，我们要理解SQL Server如何加密存储过程。SQL Server提供了一种称为透明数据加密（TDE）的功能，它可以在数据库级别加密整个数据库，...
关于SQlserver数据库的加密应用
在SQL Server中，有时出于安全考虑，我们可能会对存储过程进行加密，以防止未经授权的访问或查看其内部逻辑。本文将详细介绍如何在数据库所在的计算机上读取加密的SQL过程，以及涉及的相关技术知识。 首先，我们...
针对 SQL Server 2008 存储过程通过 With Encryption 加密方式的解密 SQL Server 2008 存储过程中使用 With Encryption 加密方式可以对存储过程进行加密保护，以防止未经授权的访问和修改。但是，在某些情况下，...
因Oracle暂不支持对视图（View）的加密，在实际工作中有时需提供给第三方只读账户，为保护知识产权，可用文中所述方法防止第三方账户查看视图（View）中的SQL代码。
SQL（Structured Query Language）是用于管理关系数据库的标准编程语言，而RSA是一种非对称加密算法，常用于数据的安全传输和存储。 RSA算法是由Ron Rivest、Adi Shamir和Leonard Adleman在1977年提出的，它是公钥...
破解 SQL加密的 存储过程，按文件中说明先创建一个存储过程。用新创建的存储过程就可以读出之前加密的存储过程了。
在SQL Server中进行DES加密是保护敏感数据的一种常见方法，特别是在C#应用程序中与数据库交互时。DES（Data Encryption Standard）是一种对称加密算法，它使用相同的密钥进行加密和解密，提供了一种相对快速的数据...
本文档“万能破解SQL存储过程加密”提供了解密SQL Server 2000中的加密存储过程的方法，这将帮助那些曾经为此困扰或寻找付费解决方案的人。 SQL Server 2000的加密是通过透明数据加密（TDE）和对象级别的加密来实现...
标题中的"SQL源码加密解密 PB源码"暗示了我们讨论的主题集中在SQL代码的保护以及PowerBuilder（PB）源代码的处理上。这通常涉及到软件开发中的安全性和知识产权保护，尤其是在多团队协作或者第三方代码集成的情景下...
本文将围绕“SQL数据加密”这一主题，详细解析如何使用SQL Server内置的功能进行数据加密，并结合给定的部分内容示例进行深入分析。 ### SQL数据加密概述 SQL Server的数据加密主要涉及以下几个概念： - **对称...
SQL字段加密技术作为保障数据安全的关键手段，其重要性不言而喻。本文将深入探讨SQL字段加密的原理、方法以及应用场景，旨在帮助读者全面理解并掌握这一重要技能。 ### SQL字段加密概述 SQL字段加密指的是在数据库...
根据提供的文件信息，本文将详细解释SQL Server中的对象加密功能，并深入探讨所提供的存储过程`sp_EncryptObject`的具体实现逻辑。 ### SQL Server 加密概述 SQL Server提供了多种方式来保护数据的安全性，其中...
首先，SQL Server本身并不提供直接查看加密存储过程源代码的功能。当存储过程被加密后，SQL Server Management Studio（SSMS）无法直接打开并显示其内容，这给数据库管理员或开发者带来了挑战。但有一些第三方工具和...
SQL破解加密视图存储过程SqlDecryptor_v1.1.0.rar.rar
- SQL脚本支持：除了可视化操作，它还支持编写和执行SQL脚本，这对于高级用户来说非常方便，可以快速执行复杂的数据库操作。 - 文件导入导出：DB Browser for SQLite支持多种数据格式的导入导出，如CSV、JSON等，...