hitTest（BitmapData.hitTest 方法）

public hitTest(firstPoint:Point, firstAlphaThreshold:Number, secondObject:Object, [secondBitmapPoint:Point], [secondAlphaThreshold:Number]) : Boolean

在一个位图图像与一个点、矩形或其它位图图像之间执行像素级的点击检测。在执行点击测试时，将不会考虑两个对象中任何一个对象的拉伸、旋转或其它变形。

如果某个图像是不透明图像，则此方法会将其视为完全不透明的矩形。两个图像必须是透明图像才能执行判断透明度的像素级点击测试。当您在测试两个透明图像时，Alpha threshold 参数将控制哪些 Alpha 通道值（从 0 到 255）将被视为是不透明的。

可用性： ActionScript 1.0；Flash Player 8

参数

firstPoint :flash.geom.Point - 定义当前 BitmapData 实例中某像素位置的点。

firstAlphaThreshold :Number - 最大的 Alpha 通道值，此点击测试将其视为不透明的。

secondObject :Object - 一个 Rectangle、Point 或 BitmapData 对象。

secondBitmapPoint :flash.geom.Point [可选] - 定义第二个 BitmapData 对象中某像素位置的点。仅当 secondObject 的值是 BitmapData 对象时使用此参数。

secondAlphaThreshold :Number [可选] - 最大的 Alpha 通道值，它在第二个 BitmapData 对象中被视为不透明的。仅当 secondObject 的值是 BitmapData 对象，并且这两个 BitmapData 对象都为透明时使用此参数。

返回

Boolean - 一个布尔值。如果进行了点击，则返回值 true ；否则，返回值 false 。

示例

下面的示例演示如何确定 BitmapData 对象是否正在与 MovieClip 发生冲突。

import flash.display.BitmapData;
import flash.geom.Point;

var myBitmapData:BitmapData = new BitmapData(100, 80, false, 0x00CCCCCC);

var mc_1:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
mc_1.attachBitmap(myBitmapData, this.getNextHighestDepth());

var mc_2:MovieClip = createRectangle(20, 20, 0xFF0000);

var destPoint:Point = new Point(myBitmapData.rectangle.x, myBitmapData.rectangle.y);
var currPoint:Point = new Point();

mc_1.onEnterFrame = function() {
    currPoint.x = mc_2._x;
    currPoint.y = mc_2._y;
    if(myBitmapData.hitTest
(destPoint, 255, currPoint)) {
        trace(">> Collision at y:" + currPoint.x + " and y:" + currPoint.y);
    }
}

mc_2.startDrag(true);

function createRectangle(width:Number, height:Number, color:Number):MovieClip {
    var depth:Number = this.getNextHighestDepth();
    var mc:MovieClip = this.createEmptyMovieClip("mc_" + depth, depth);
    mc.beginFill(color);
    mc.lineTo(0, height);
    mc.lineTo(width, height);
    mc.lineTo(width, 0);
    mc.lineTo(0, 0);
    return mc;
}