关于Flex的DataGrid的应用拓展（二）

    
      在使用DataGrid的过程中，用户可能会要求根据某个条件，整行disable。如根据active字段是否等于true来判断这行是否disable。这个特性在DataGrid是不存在的，因此需要拓展。

步骤如下：

1）实现DataGrid继承来拓展一些属性。

package {
    import mx.controls.DataGrid;
    import mx.controls.listClasses.IListItemRenderer;
    import mx.core.ClassFactory;
    
    public class CheckSelectedDataGrid extends DataGrid
    {
        public function CheckSelectedDataGrid()
        {
            super();
            this.itemRenderer= new ClassFactory(CheckDisableLabel);  //added custom field
        }
        
        //check current row if it should be selected.
        override	protected function selectItem(item:IListItemRenderer,
                                                  shiftKey:Boolean, ctrlKey:Boolean,
                                                  transition:Boolean = true):Boolean{
            var seletedData:Object=item.data;
            
            if(seletedData.active=="false"){
                return false;
            }else{
                return  super.selectItem(item,shiftKey,ctrlKey,transition);
            }
        }
    }
}

注意：以上实现了两件事情。1）创建了一个单元格的实现工厂，这个实现类下一步介绍。2）既然disable就应该尽量避免用户选中这一行，这就是以上覆盖方法需要做的事情。

2）实现上面指定的工厂类：

package 
{
    import mx.controls.Label;

    public class CheckDisableLabel extends Label
    {
        public function CheckDisableLabel()
        {
        }
        
        //check current field if it should be disabled
        override   public function set data(value:Object):void{
            super.data=value;
            if(value&&value.hasOwnProperty("active")&&value.active!="true"){
                this.enabled=false;
            }else{
                this.enabled=true;
            }
        }
    }
}

注：这样就完成了一个简单的正行disable的功能。使用的时候跟其他DataGrid没有什么不同。这里就举例子如何使用了。这里仅仅是个demo，应用于项目还需要

自己修改一下。