http://www.phpq.net/oracle/oracle-cursors-syntax.html
Oracle Cursors语法总结
关于Oracle Cursors的语法总结,Oracle Cursors是用来查询数据库,获取记录集合(结果集)的指针,可以让开发者一次访问一行结果集,在每条结果集上作操作。
一.Oracle的Cursors概念:
游标:用来查询数据库,获取记录集合(结果集)的指针,可以让开发者一次访问一行结果集,在每条结果集上作操作。
二.Oracle的Cursors分类:
1.静态游标:
分为显式游标和隐式游标。
2.REF游标:
是一种引用类型,类似于指针。
三.Oracle的Cursors详细内容:
1.显式游标:
CURSOR游标名(参数) [返回值类型] IS
Select语句
生命周期:
a.打开游标(OPEN)
解析,绑定。。。不会从数据库检索数据
b.从游标中获取记录(FETCH INTO)
执行查询,返回结果集。通常定义局域变量作为从游标获取数据的缓冲区。
c.关闭游标(CLOSE)
完成游标处理,用户不能从游标中获取行。还可以重新打开。
选项:参数和返回类型
set serveroutput on
declare
cursor emp_cur ( p_deptid in number) is
select * from employees where department_id = p_deptid;
l_emp employees%rowtype;
begin
dbms_output.put_line('Getting employees from department 30');
open emp_cur(30);
loop
fetch emp_cur into l_emp;
exit when emp_cur%notfound;
dbms_output.put_line('Employee id '|| l_emp.employee_id || ' is ');
dbms_output.put_line(l_emp.first_name || ' ' || l_emp.last_name);
end loop;
close emp_cur;
dbms_output.put_line('Getting employees from department 90');
open emp_cur(90);
loop
fetch emp_cur into l_emp;
exit when emp_cur%notfound;
dbms_output.put_line('Employee id '|| l_emp.employee_id || ' is ');
dbms_output.put_line(l_emp.first_name || ' ' || l_emp.last_name);
end loop;
close emp_cur;
end;
2.隐式游标:
不用明确建立游标变量,分两种:
a.在PL/SQL中使用DML语言,使用ORACLE提供的名为SQL的隐示游标
b.CURSOR FOR LOOP,用于for loop语句
a.举例:
declare
begin
update departments set department_name=department_name;
--where 1=2;
dbms_output.put_line('update '|| sql%rowcount ||' records');
end;
/
b.举例:
declare
begin
for my_dept_rec in ( select department_name, department_id from departments)
loop
dbms_output.put_line(my_dept_rec.department_id || ' : ' || my_dept_rec.department_name);
end loop;
end;
/
c.举例:
单独select
declare
l_empno emp.EMPLOYEE_ID%type;
-- l_ename emp.ename%type;
begin
select EMPLOYEE_ID
into l_empno
from emp;
--where rownum =1;
dbms_output.put_line(l_empno);
end;
/
使用INTO获取值,只能返回一行。
游标属性:
%FOUND:变量最后从游标中获取记录的时候,在结果集中找到了记录。
%NOTFOUND:变量最后从游标中获取记录的时候,在结果集中没有找到记录。
%ROWCOUNT:当前时刻已经从游标中获取的记录数量。
%ISOPEN:是否打开。
Declare
Cursor emps is
Select * from employees where rownum<6 order by 1;
Emp employees%rowtype;
Row number :=1;
Begin
Open emps;
Fetch emps into emp;
Loop
If emps%found then
Dbms_output.put_line('Looping over record '||row|| ' of ' || emps%rowcount);
Fetch emps into emp;
Row := row + 1;
Elsif emps%notfound then
Exit; ---exit loop, not IF
End if;
End loop;
If emps%isopen then
Close emps;
End if;
End;
/
显式和隐式游标的区别:
尽量使用隐式游标,避免编写附加的游标控制代码(声明,打开,获取,关闭),也不需要声明变量来保存从游标中获取的数据。
3.REF CURSOR游标:
动态游标,在运行的时候才能确定游标使用的查询。分类:
1.强类型(限制)REF CURSOR,规定返回类型
2.弱类型(非限制)REF CURSOR,不规定返回类型,可以获取任何结果集。
TYPE ref_cursor_name IS REF CURSOR [RETURN return_type]
Declare
Type refcur_t is ref cursor;
Type emp_refcur_t is ref cursor return employee%rowtype;
Begin
Null;
End;
/
强类型举例:
declare
--声明记录类型
type emp_job_rec is record(
employee_id number,
employee_name varchar2(50),
job_title varchar2(30)
);
--声明REF CURSOR,返回值为该记录类型
type emp_job_refcur_type is ref cursor
return emp_job_rec;
--定义REF CURSOR游标的变量
emp_refcur emp_job_refcur_type;
emp_job emp_job_rec;
begin
open emp_refcur for
select e.employee_id,
e.first_name || ' ' ||e.last_name "employee_name",
j.job_title
from employees e, jobs j
where e.job_id = j.job_id and rownum < 11 order by 1;
fetch emp_refcur into emp_job;
while emp_refcur%found loop
dbms_output.put_line(emp_job.employee_name || '''s job is ');
dbms_output.put_line(emp_job.job_title);
fetch emp_refcur into emp_job;
end loop;
end;
分享到:
相关推荐
设有学生表student(学号sno, 姓名sname, 年龄 sage,系别dept)、课程表Course(课程号cno,课程名称cname)和选课表sc(学号sno,课程号cno,成绩grade),用Oracle PL/SQL语言设计一个名为pkg_student程序包,要求: ...
Oracle数据库是全球广泛使用的大型关系型数据库管理系统之一,其语法丰富多样,涵盖了数据查询、数据操纵、数据定义和数据控制等多个方面。以下是对"Oracle语法大全"这一主题的详细阐述。 1. 数据查询(DQL):...
描述Oracle中游标的基本知识,纯英文,国外大学教授使用的教学笔记
Oracle 参数 open_cursors 与 session_cached_cursors 详解 Oracle 数据库中,open_cursors 和 session_cached_cursors 是两个重要的参数,它们对 Oracle 的运行性能产生了直接的影响。本文将详细解释这两个参数的...
以下是对标题"ORACLE调优文档总结"和描述中所述知识点的详细说明: 1. **数据库参数设置**: Oracle数据库的性能很大程度上取决于其配置参数。例如,`SGA (System Global Area)` 包含了共享池、数据缓冲区高速缓存...
本文将基于“oracle 日常所用总结”的主题,深入探讨Oracle中的常用命令、触发器、游标、视图以及等待事件,旨在帮助用户更好地理解和应用这些关键概念。 1. **Oracle常用命令**: - 数据查询:`SELECT`语句是查询...
查看processes和sessions参数 第一步,在cmd命令行,输入sqlplus 第二步,根据提示输入用户名与密码
Use Of Cursors And Parallel Cursors In SAP ABAP
"Oracle 执行计划详解" Oracle 执行计划是数据库性能优化的关键。为了更好地理解和优化 Oracle 数据库的执行计划,我们需要了解执行计划的生成过程、优化方法和执行计划的解读方法。 执行计划生成过程 执行计划的...
- Opened cursors current:显示当前打开的游标数。 - Total file opens:总计的文件打开次数。 通过这些度量,你可以了解数据库在负载测试中的性能表现,如资源利用率、网络通信效率等,从而分析和优化应用程序...
总结来说,创建Oracle数据库在UNIX环境下涉及的主要知识点包括环境变量配置、参数文件的编辑、控制文件、内存结构的设定、归档日志策略、安全性配置以及分布式事务管理。理解并掌握这些知识点,将能帮助你顺利地在...
* session_cached_cursors:该参数控制着 Oracle XE 缓存游标的数量,缓存游标可以加速查询速度。 * session_max_open_files:该参数控制着 Oracle XE 可以打开的文件数量,高于这个值将导致错误。 * sessions:该...
总结起来,Oracle数据库通过表空间、分区、存储过程、函数、游标和索引等机制,实现了高效、安全和可扩展的数据管理。理解并熟练掌握这些概念对于优化Oracle数据库性能和进行高效软件开发至关重要。
Oracle Webcenter 是一款企业级的协作和社交软件平台,它提供了丰富的工具来增强团队合作、信息共享和工作流程管理。本文将详细介绍如何安装 Oracle Webcenter,主要包括四个主要步骤:安装数据库、运行 Repository ...
oracle数据库忽然连不上了,一查是游标数量超了。 1.查看游标数 show parameter open_cursors 2.修改游标数 alter system set open_cursors = 10000; 3.获取打开的游标数 select o.sid, osuser, machine, count...
本数据库(oracle)7个实验报告用于和大家交流,我将这次报告所需要的表和数据材料能够拿出来的都放了在同一个包里的,希望大家能够去看看并且多提点意见,同时我将第一个报告(手工创建数据库库)的记录也放在了包...
其他如“9.pdf”、“3.pdf”、“4.pdf”等文件,很可能是对SQL基础语法的详细讲解,包括数据类型、DML(Data Manipulation Language)操作如INSERT、UPDATE、DELETE,以及DDL(Data Definition Language)用于创建、...
Oracle数据库是全球广泛使用的大型关系型数据库管理系统,其稳定性和功能强大深受企业青睐。然而,在日常操作和维护中,我们可能会遇到各种错误,这些错误通常会以“ORA-”开头的错误码形式出现。"Oracle错误码大全...
Inceptor SQL 语法是基于 Oracle 方言的 PL/SQL 手册,它提供了详细的语法规则和实践指南,以帮助开发者更好地使用 Inceptor PL/SQL。 常量和变量 在 PL/SQL 中,可以用常量和变量存储值。常量的值不能改变,而...
总结,Oracle数据库调优是个复杂且系统的工程,涉及到硬件、操作系统、数据库架构、SQL优化等多个方面。理解并应用上述调优策略,结合实际业务场景,能够有效提升数据库性能,降低系统响应时间,从而提高用户满意度...