数据库游标（Oracle）

游标的概念

游标是SQL的一个内存工作区，由系统或用户以变量形式定义。

游标的作用是用于临时存储从数据库中提取的数据块。

为什么要用游标？数据库的数据是存放在磁盘中的，游标是把数据从磁盘中调到计算机内存中进行处理，最后将处理结果显示出来或者最终写回数据库，这样可以提高数据处理的效率，因为频繁的磁盘数据交换会降低效率。

游标有两种类型：隐式游标和显示游标。

隐式游标：对于SELECT...INTO...语句（一次只能从数据库中提取一行记录）和DML（数据操纵语言，也就是INSERT语句、UPDATE语句和DELETE语句），系统都会采用隐式游标。

显示游标：对于结果集多于1条记录的SELECT语句，需要程序员自己定义一个显示游标。

隐式游标

隐式游标的四个属性

%FOUNT	值true代表单行查询语句或DML语句操作成功
%NOTFOUNT	与%Found相反
%ISOPEN	DML执行中为true，执行结束后为false
%ROWCOUNT	代表DML语句成功执行的数据行数

使用隐游标的一个例子：

SET SERVEROUTPUT ON   
        BEGIN  
        UPDATE emp SET sal=sal+100 WHERE empno=1234;  
        IF SQL%FOUND THEN   
        DBMS_OUTPUT.PUT_LINE('成功修改雇员工资！');  
        COMMIT;   
        ELSE  
        DBMS_OUTPUT.PUT_LINE('修改雇员工资失败！');  
        END IF;   
        END;  

显示游标

显示游标的四个属性

%FOUNT	最近的FETCH语句返回一行记录则true，否则为false
%NOTFOUNT	与%Found相反
%ISOPEN	游标打开时为true，否则为false
%ROWCOUNT	获取FETCH语句返回的行数

显示游标的使用分以下4个步骤：

1. 声明游标
2. 打开游标
3. 提取数据
4. 关闭游标

声明游标：

CURSOR 游标名[(参数1 数据类型[，参数2 数据类型...])] IS SELECT语句;

参数是可选部分

打开游标：

OPEN 游标名[(实际参数1[，实际参数2...])];

参数是可选部分，打开游标时，结果集就被送到的游标工作区

提取数据：

FETCH 游标名 INTO 变量名1[，变量名2...];

或

FETCH 游标名 INTO 记录变量;

游标打开后有一个指针指向数据区，FETCH语句一次返回指针所指的一行数据，要返回多行需重复执行，可以使用循环语句来实现。控制循环可以通过判断游标的属性来进行。

第一种FETCH格式：变量名是用来从游标中接收数据的变量，需要事先定义。变量的个数和类型应与SELECT语句中的字段变量的个数和类型一致。

第二种FETCH格式：一次将一行数据提取到记录变量中，需要使用%ROWTYPE事先定义记录变量，这种形式使用起来比较方便，不必分别定义和使用多个变量。定义记录变量的方法：变量名 表名|游标名%ROWTYPE; 其中的表必须存在，游标名也必须先定义。

关闭游标：

CLOSE 游标名;

显式游标打开后，必须显式地关闭。游标一旦关闭，游标占用的资源就被释放，游标变成无效，必须重新打开才能使用。

下面是几个关于怎么使用显示游标的例子：

【例子1】用游标提取emp表中7788雇员的名称和职务（第一种FETCH）

SET SERVEROUTPUT ON  
    DECLARE   
        v_ename VARCHAR2(10);  
        v_job VARCHAR2(10);  
        CURSOR emp_cursor IS
            SELECT ename,job FROM emp WHERE empno=7788;  
    BEGIN  
        OPEN emp_cursor;  
        FETCH emp_cursor INTO v_ename,v_job;  
        DBMS_OUTPUT.PUT_LINE(v_ename||','||v_job);  
        CLOSE emp_cursor;  
    END;

【例子2】用游标提取emp表中7788雇员的姓名、职务和工资（第二种FETCH）

SET SERVEROUTPUT ON  
    DECLARE  
        CURSOR emp_cursor IS
            SELECT ename,job,sal FROM emp WHERE empno=7788;  
    emp_record emp_cursor%ROWTYPE;  
  BEGIN  
        OPEN emp_cursor;      
    FETCH emp_cursor INTO emp_record;  
    DBMS_OUTPUT.PUT_LINE(emp_record.ename||','|| emp_record.job||','|| emp_record.sal);  
    CLOSE emp_cursor;  
  END; 

【例子3】用游标提取种类是1的所有书的标题（LOOP）

DECLARE
    CURSOR BOOKS_CURSOR IS
        SELECT TITLE FROM BOOKS WHERE CATEGORY_ID = 1;
    V_TITLE     BOOKS.TITLE%TYPE;
    V_ONE_BOOK  BOOKS%ROWTYPE;
BEGIN
    OPEN BOOKS_CURSOR;
    LOOP
        FETCH BOOKS_CURSOR INTO V_TITLE;
        EXIT WHEN BOOKS_CURSOR%NOTFOUND;
        DBMS_OUTPUT.PUT_LINE(BOOKS_CURSOR%ROWCOUNT || '. ' || V_TITLE);
    END LOOP;
    CLOSE BOOKS_CURSOR;
END;

【例子4】用游标提取种类是1的所有书的标题（FOR）

DECLARE
    CURSOR BOOKS_CURSOR IS
        SELECT TITLE FROM BOOKS WHERE CATEGORY_ID = 1;
    V_ONE_BOOK  BOOKS%ROWTYPE;
    V_COUNT     NUMBER(2) := 0;
BEGIN
    FOR V_ONE_BOOK IN BOOKS_CURSOR LOOP
        V_COUNT := V_COUNT + 1;
        DBMS_OUTPUT.PUT_LINE(V_COUNT || '. ' || V_ONE_BOOK.TITLE);
    END LOOP;
END;