oracle游标

一 游标是什么

游标字面理解就是游动的光标。

用数据库语言来描述：游标是映射在结果集中一行数据上的位置实体，有了游标，用户就可以访问结果集中的任意一行数据了，将游标放置到某行后，即可对该行数据进行操作，例如提取当前行的数据等。

二 游标的分类

隐式游标和显式游标

隐式游标

隐式游标：PL/SQL为所有SQL操作语句（包括返回一行的select)隐式声明游标，称为隐式游标的原因是用户不能直接命名和控制此类游标。当用户在PL/SQL中使用数据操作语言（DML）时，Oracle预先定义一个名为SQL的隐式游标，通过，通过检查隐式游标的属性可以获取与最近执行的SQL语句相关的信息。
在执行DML语句之后，隐式游标的属性包括：%FOUND只有DML语句影响一行或多行时，%FOUND属性才返回TRUE

隐式游标是ORACLE为所有操纵语句（包括只返回单行数据的查询语句）自动声明和操作的一种游标

示例一
declare
   begin
       for my_dept_rec in ( select * from ent_product_info)
           loop
               dbms_output.put_line(my_dept_rec.product_code || ' : ' || my_dept_rec.product_name);
           end loop;
   end;  
/

示例二
declare
   begin
       update ent_product_info set product_code=product_code;
       dbms_output.put_line('update '|| sql%rowcount ||' records');
   end;
/ 

示例三
DECLARE
   BEGIN
      UPDATE ent_product_info SET product_code=product_code
         WHERE product_code='1000000002';
      IF SQL%FOUND THEN
           DBMS_OUTPUT.PUT_LINE('表以更新');
      ELSE
           DBMS_OUTPUT.PUT_LINE('编号未找到');
      END IF;
   END;
/

示例四
--同上在command window中执行
SET SERVEROUTPUT ON
   BEGIN
      UPDATE ent_product_info SET product_code=product_code
         WHERE product_code='1000000002';
      IF SQL%FOUND THEN
           DBMS_OUTPUT.PUT_LINE('表以更新');
      ELSE
           DBMS_OUTPUT.PUT_LINE('编号未找到');
      END IF;
   END;
/

显式游标

显示游标是由用户声明和操作的一种游标

显式游标的使用需要4步：

1. 声明游标

CURSOR mycur(vartype number) is

select emp_no,emp_zc from cus_emp_basic

where com_no = vartype;

2. 打开游标

open mycur(000627)

注：000627是参数

3. 读取数据

fetch mycur into varno, varprice;

4. 关闭游标

close mycur;

三 游标的属性

oracle 游标有4个属性：%ISOPEN，%FOUND，%NOTFOUND，%ROWCOUNT。

%ISOPEN判断游标是否被打开，如果打开%ISOPEN等于true,否则等于false；

%FOUND %NOTFOUND判断游标所在的行是否有效，如果有效，则%FOUNDD等于true，否则等于false；

%ROWCOUNT返回当前位置为止游标读取的记录行数。

四 示例

--带参数游标
declare
    varno varchar2(10);
    varname varchar2(128);
    varfee number;
    CURSOR mycur(productid varchar2) is
        select product_code,product_name,product_fee from ent_product_info
            where product_code = productid;
    begin
        if mycur%isopen = false then
            open mycur('1000000012');
        end if;
    fetch mycur into varno,varname,varfee;
    while mycur%found
    loop
        dbms_output.put_line(varno||','||varname||','||varfee);
        if mycur%rowcount=2 then
          dbms_output.put_line(mycur%rowcount||','
              ||varno||','||varname||','||varfee);
            exit;
        end if;
        fetch mycur into varname,varname,varfee;
    end loop;
    close mycur;
end;
/
--不带参数游标
declare
    varno varchar2(10);
    varname varchar2(128);
    varfee number;
    CURSOR mycur is
        select product_code,product_name,product_fee from ent_product_info;
    begin
        if mycur%isopen = false then
            open mycur;
        end if;
    fetch mycur into varno,varname,varfee;
    while mycur%found
    loop
        dbms_output.put_line(varno||','||varname||','||varfee);
        if mycur%rowcount=21 then
            dbms_output.put_line(mycur%rowcount||','
              ||varno||','||varname||','||varfee);
            exit;
        end if;
        fetch mycur into varno,varname,varfee;
    end loop;
    close mycur;
end;
/
注: mycur%rowcount=2表示获取游标前两条数据就退出;

--for循环
declare
    cursor mycur is
        select product_code,product_name,product_fee from ent_product_info;
    begin
        for product in mycur loop
            dbms_output.put_line(product.product_code||','||product.product_name||','||product.product_fee);
        end loop; 
    end;
/
注：游标for循环示显示游标的一种快捷使用方式，它使用for循环依次读取结果集中的行数据，当form循环开始时，游标自动打开（不需要open），每循环一次系统自动读取游标当前行的数据（不需要fetch)，当退出for循环时，游标被自动关闭（不需要使用close）。使用游标for循环的时候不能使用open语句，fetch语句和close语句，否则会产生错误。

--自定义的数据类型
declare
    type product is record
    (
        varno ent_product_info.product_code%type,
        varname ent_product_info.product_name%type,
        varfee ent_product_info.product_fee%type
    );
    product1 product;
    cursor mycur is
        select product_code,product_name,product_fee from ent_product_info;
    begin
        if mycur%isopen = false then
            open mycur;
        end if;
        loop
            fetch mycur into product1;
            exit when mycur%notfound;
            dbms_output.put_line(product1.varno||','||product1.varname||','||product1.varfee);
        end loop;
        close mycur;
    end;
/