red5自学篇（5）

一边录像，一边看。其实这就是现在视频的真谛。red5也可以实现这个功能，代码很简单，不过写了很久。。。。。

 

 

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute"
    creationComplete="init()">
    <mx:Script>
        <![CDATA[
            import mx.controls.Alert;
            private var nc:NetConnection = null;
            private var ns:NetStream = null;
            private var video:Video = null;
            private var camera:Camera = null;//定义一个摄像头
            private var mic:Microphone; //定义一个麦克风

            private var rtmp_url:String = "rtmp://192.168.61.115/red5_app";

            private var play_url:String = "rtmp://192.168.61.115/red5_app";
            private var nc_play:NetConnection = null;
            private var ns_play:NetStream = null;
            private var video_play:Video = null;

            private var videoName:String = ""; //视频保存名字

            private function init():void{
                //nc = new NetConnection();
                setupCameraAndMic();
            }

            private function setupCameraAndMic():void{
                camera = Camera.getCamera();
                if(camera != null){
                    camera.addEventListener(StatusEvent.STATUS,cameraStatus);
                    camera.setMode(128,96,12);
                    camera.setQuality(0,100);
                    video = new Video();
                    video.width = 128;
                    video.height = 96;
                    video.attachCamera(camera);
                    recordVideo.addChild(video);
                }
                mic = Microphone.getMicrophone();
                if(mic != null){
                    mic.addEventListener(StatusEvent.STATUS,micStatus);
                    mic.setSilenceLevel(0,-1); //设置麦克风保持活动状态并持续接收集音频数据
                    mic.gain = 80; //设置麦克风声音大小
                }
            }

            private function cameraStatus(event:StatusEvent):void{
                if(!camera.muted){
                    begin.enabled = true;
                    //error_label.text = error_label.text + "1";
                }else{
                    //error_label.text = error_label.text + "  无法找到摄像头"
                }
                //camera.removeEventListener(StatusEvent.STATUS,cameraStatus);
            }

            /* 好像麦克风没法检测，测试过拔掉麦克风，但是没效果 */
            private function micStatus(event:StatusEvent):void{
                if(!mic.muted){
                    begin.enabled = true;
                    //error_label.text = error_label.text + "2";
                }else{
                    //error_label.text = error_label.text + "  无法找到麦克风";
                }
                //mic.removeEventListener(StatusEvent.STATUS,micStatus);
            }

            /*点击 开始录像 按钮*/
            private function clickStartRecord():void{
                nc = new NetConnection();
                nc.addEventListener(NetStatusEvent.NET_STATUS,nsHandler);
                nc.connect(rtmp_url); //连接red5
                //doRecord();

            }

            private function nsHandler(evt:NetStatusEvent):void{
                if(evt.info.code == "NetConnection.Connect.Success"){ //如果连接成功
                    //error_text.text = evt.info.code;
                    doRecord();
                }else{
                    Alert.show("连接失败");
                }
            }

            /*开始录像*/
            private function doRecord():void{
                if(video != null){
                    video.clear();
                    recordVideo.removeChild(video);
                    video = new Video();
                    video.width = 128;
                    video.height = 96;
                    video.attachCamera(camera);
                    recordVideo.addChild(video);
                }
                ns = new NetStream(nc);
                ns.attachCamera(camera);
                ns.attachAudio(mic);
                videoName = "vincent_"+Math.random()+getTimer();
                ns.publish(videoName,"record");
                begin.enabled = false;
                end.enabled = true;
                doPlay();
            }

            function doPlay():void{
                nc_play = new NetConnection();
                nc_play.addEventListener(NetStatusEvent.NET_STATUS,ncPlayHandler);
                nc_play.connect(play_url);

                //playVideo.source = play_url+videoName+".flv";
                //error_text.text = ;
            }


            private function ncPlayHandler(evt:NetStatusEvent):void{
                if(evt.info.code == "NetConnection.Connect.Success"){ //如果连接成功
                    error_text.text = evt.info.code;
                    //error_text.text = "4"
                    ns_play = new NetStream(nc_play);
                    /*这里我曾经迷惑了很久，记得这个videoName是不带flv后缀的，如果带了那就是不行了*/
                    ns_play.play(videoName);
                    //error_text.text = "5"
                    video_play = new Video();
                    video_play.width = 320;
                    video_play.height = 240;
                    video_play.attachNetStream(ns_play);
                    playVideo.addChild(video_play);
                    //error_text.text = "6"
                }else{
                    Alert.show("连接失败");
                }
            }

            private function clickend():void{
                ns.close();
                //nc.close();
                video.clear();
                ns_play.close();
                //nc_play.close();
                video_play.clear();
                recordVideo.removeChild(video);
                begin.enabled = true;
                end.enabled = false;

                init();/*重新初始化Camera，否则Camera会默认使用完了，不再显示图像*/
            }
        ]]>
    </mx:Script>
    <mx:Panel x="264" y="362" width="167" height="157.6" layout="absolute">
        <mx:VideoDisplay x="9" y="10" width="128" height="96" id="recordVideo"/>
    </mx:Panel>
    <mx:Button x="73" y="495.6" enabled="false" label="开始视频" fontSize="12" id="begin"
        click="clickStartRecord()"/>
    <mx:Button x="178" y="495.6" enabled="false" label="结束视频" fontSize="12" id="end"
        click="clickend()"/>
    <mx:Panel x="73" y="47" width="358" height="307" layout="absolute">
        <mx:VideoDisplay x="9" y="10" width="320" height="240" id="playVideo"/>
    </mx:Panel>
    <mx:Text x="73" y="372" id="error_text" text="Text" width="183" height="53.6"/>
    <!--
    <mx:TextInput x="73" y="433" id="playName" fontSize="12"/>
    <mx:Button x="73" y="463" label="播放" id="playButton" fontSize="12" click="doPlay();"/>
    -->
</mx:Application>