强类型数值计算

以前曾经讨论过使用typedef来完成强类型的数值计算，最终遇到的问题是D里面没办法定义进行全局运算符重载。

最近在struct上找到点灵感，把基本类型用struct包装后使用，就可以重载运算符了，当然效率也是有保证的，D前几个版本已经完成了NRVO，struct也可以在栈上分配，所以不用担心性能，不过编译时注意打开-O选项。

简单测试了一下，性能与基本类型基本上没有差别：

template WrapStruct(T)
{
	T value;

	T opCast()
	{
		return value;
	}

	typeof(*this) opAssign(T)(T v)
	{
		value = v;
		return *this;
	}

	static typeof(*this) opCall(T)(T v)
	{
		typeof(*this) result;
		result.value = v;
		return result;
	}
}


struct Length
{
	mixin WrapStruct!(float);

	Time opDiv(Speed speed)
	{
		return Time(value / speed.value);
	}
	
	Speed opDiv(Time time)
	{
		return Speed(value / time.value);
	}

	char[] toString()
	{
		return std.string.format("%f m", value);
	}
}

struct Speed
{
	mixin WrapStruct!(float);

	Length opMul(Time time)
	{
		return Length(value * time.value);
	}

	char[] toString()
	{
		return std.string.format("%f m/s", value);
	}
}

struct Time
{
	mixin WrapStruct!(float);

	Length opMul(Speed speed)
	{
		return Length(value * speed.value);
	}

	char[] toString()
	{
		return std.string.format("%f s", value);
	}
}


import std.stdio;
import std.date;

void main()
{
	{
		Length length = 30;
		Speed speed = 3;
		Time time = length / speed;
		assert(cast(float)time == 10);

		time = 5;
		speed = length / time;
		assert(cast(float)speed == 6);
	}

	{
		long start = getUTCtime();
		float length = 3;
		float speed = 1.5;
		float time;
		for (int i=0; i<100000000; ++i)
		{
			time = length / speed;
		}
		writefln(getUTCtime() - start);
	}

	{
		long start = getUTCtime();
		Length length = 3;
		Speed speed = 1.5;
		Time time;
		for (int i=0; i<100000000; ++i)
		{
			time = length / speed;
		}
		writefln(getUTCtime() - start);
	}
}

评论

12 楼 qiezi 2007-04-12  

是这样的 

11 楼 soulmachine 2007-04-12  

我以为你能用C++的宏和typedef引入新的类型，开始很是惊奇。现在你的意思是：用C++的带参宏取代D的模板。我的意思再明确一下，不知对不对：C++中引入新的类型只能用struct或class自定义，而D中则多了一个手段，就是typedef。

10 楼 qiezi 2007-04-12  

我说的typedef就是D里面的，本身就是强类型的：

typedef int Length;
typedef int Time;

这2个类型不能相互赋值，除非强制转型。就连int要赋给Length也要转型，这可能不如上面写的struct方便。改用struct的主要原因就是D里面无法重载全局运算符。

我说C++宏可以实现mixin的功能，这个功能原本就是宏做的事啊。演示代码把上面的D模板改成宏就行了，语法上处理成C++的，肯定也很容易写。

9 楼 soulmachine 2007-04-12  

#include <iostream>

typedef int  myInt1;
typedef int  myInt2;

int main(int argc, char* argv[])
{
myInt1 a = 1;
myInt2 b = 2;
b = a;
std::cout << b;
return 0;
}
或
#include <iostream>

#define myInt1 int 
#define myInt2 int 

int main(int argc, char* argv[])
{
myInt1 a = 1;
myInt2 b = 2;
b = a;
std::cout << b;
return 0;
}

在C++中宏和typedef只是为类型取了别名，并不象D中的typedef那样引入了新的类型。qiezi能否给出一段用宏或typedef提供更丰富类型的代码？

8 楼 qiezi 2007-04-12  

C++也可以用宏的，D的语法是要简洁一些。原本想用typedef，更轻量一些，后来发现还是得用struct。

7 楼 soulmachine 2007-04-12  

在C++把同一个基本类型提升为更强的类型，似乎只能用struct 或class对其进行封装(目前只知道这种做法)。你的这段代码核心是一样的，用了struct提供更强的类型，只不过你用了D特有的mixin减少了代码量，看起来简洁了许多

6 楼 qiezi 2007-04-11  

在不降低效率的前提下，提供更强的类型，当然也就是更丰富的值语义。C++也有类似的库这样实现，不过C++模板编译效率无法忍受，D在这方面要好得多。

5 楼 oldrev 2007-04-10  

今天够多产的啊，哈哈

4 楼 h_rain 2007-04-10  

哈哈哈哈！还行，我猜到了！
呵呵，这回也把附加功能加入了！

漂亮！

3 楼 qiezi 2007-04-10  

Length length = 3;
Time time = 2;
writefln("Length: ", length, ", Time: ", time, ", speed: ", length / time);

输出：

引用

Length: 3.000000 m, Time: 2.000000 s, speed: 1.500000 m/s

2 楼 qiezi 2007-04-10  

类型安全啊，Time * Time是不能编译通过的，当然你可以定义Length * Length结果是一个面积，你Length * Length的结果赋给一个Length或是Time都是没办法编译通过的，虽然它们只包含一个数值。有些数学(或物理？)库比较需要这种，当然我只简单探讨了一下，深入了我就外行了。

1 楼 h_rain 2007-04-10  

封装的很漂亮！

时间*速度=长度
速度*时间=长度
长度/速度=时间
长度/时间=速度

呵呵，很有趣！

只是，我没有明白，这种封装用于什么用途才有实际价值？
安全？附加功能？高层抽象？