Array

sort ()

方法

 

对数组中的元素进行排序。此方法按 Unicode 值排序。（ASCII 是 Unicode 的一个子集。）

默认情况下，Array。sort() 按以下方式进行排序：

• 排序区分大小写（Z 优先于 a）。
• 按升序排序（a 优先于 b）。
• 修改该数组以反映排序顺序；在排序后的数组中不按任何特定顺序连续放置具有相同排序字段的多个元素。
• 元素无论属于何种数据类型，都作为字符串进行排序，所以 100 在 99 之前，这是因为 "1" 的字符串值小于 "9" 的字符串值。

如果要使用与默认设置不同的设置对数组进行排序，可以使用 ...args 参数说明中 sortOptions 部分所描述的某种排序选项，也可以创建自定义函数来进行排序。如果创建自定义函数，请调用 sort() 方法，并将自定义函数的名称作为第一个参数 (compareFunction)。

 

参数

... args — 指定一个比较函数和确定排序行为的一个或多个值的参数。 此方法使用语法和参数顺序 Array.sort(compareFunction, sortOptions)，其参数定义如下： compareFunction - 一个用来确定数组元素排序顺序的比较函数。此参数是可选的。比较函数应该用两个参数进行比较。给定元素 A 和 B，compareFunction 的结果可具有以下三个值之一： s-1，如果 A 应在排序后的序列中出现在 B 之前 0，如果 A 等于 B 1，如果 A 应在排序后的序列中出现在 B 之后 sortOptions - 一个或多个数字或定义的常数，相互之间由 |（按位 OR）运算符隔开，它们将排序的行为从默认行为更改为其它行为。此参数是可选的。下面是 sortOptions 可接受的值： 1 或 Array.CASEINSENSITIVE 2 或 Array.DESCENDING 4 或 Array.UNIQUESORT 8 或 Array.RETURNINDEXEDARRAY 16 或 Array.NUMERIC 有关详细信息，请参阅 Array.sortOn() 方法。 注意：Array.sort() 方法是在 ECMAScript (ECMA-262) 第 3 版语言规范中定义的，而数组排序方法是 ECMA-262 的扩展。

 

返回

Array — 返回值取决于您是否传递任何参数，如以下列表中所述： 如果为 ...args 参数的 sortOptions 变量指定值 4 或 Array.UNIQUESORT，并且所排序的两个或更多个元素具有相同的排序字段，则 Flash 返回值 0 并且不修改数组。 如果为 ...args 参数的 sortOptions 变量指定值 8 或 Array.RETURNINDEXEDARRAY，则 Flash 返回排序后的索引数值数组以反映排序结果，并且不修改数组。 否则，Flash 不返回任何内容并修改该数组以反映排序顺序。

另请参见

| (bitwise OR)
Array.sortOn()

示例

下面的代码创建 Array 对象 vegetables，其中包含元素 [spinach, green pepper, cilantro, onion, avocado]。然后，通过 sort() 方法对该数组进行排序，调用该方法时不带参数。结果是 vegetables 按字母顺序排序 ([avocado, cilantro, green pepper, onion, spinach])。

var vegetables:Array = new Array("spinach",
                 "green pepper",
                 "cilantro",
                 "onion",
                 "avocado");

trace(vegetables); // spinach,green pepper,cilantro,onion,avocado
vegetables.sort();
trace(vegetables); // avocado,cilantro,green pepper,onion,spinach

下面的代码创建 Array 对象 vegetables，其中包含元素 [spinach, green pepper, Cilantro, Onion, and Avocado]。然后，通过 sort() 方法对该数组进行排序，第一次调用该方法时不带参数，其结果是 [Avocado,Cilantro,Onion,green pepper,spinach]。然后再次调用 sort()（对 vegetables），调用时将 CASEINSENSITIVE 常数作为参数。结果是 vegetables 按字母顺序排序 ([Avocado, Cilantro, green pepper, Onion, spinach])。

var vegetables:Array = new Array("spinach",
                 "green pepper",
                 "Cilantro",
                 "Onion",
                 "Avocado");

vegetables.sort();
trace(vegetables); // Avocado,Cilantro,Onion,green pepper,spinach
vegetables.sort(Array.CASEINSENSITIVE);
trace(vegetables); // Avocado,Cilantro,green pepper,Onion,spinach

下面的代码创建空的 Array 对象 vegetables，然后通过五次调用如下方法来填充该数组：push()。每次调用 push() 时，都创建一个新的 Vegetable 对象（通过调用 Vegetable() 构造函数，该构造函数接受 String (name) 和 Number (price) 对象）。使用所显示的值调用 push() 五次，会生成下面的数组：[lettuce:1.49, spinach:1.89, asparagus:3.99, celery:1.29, squash:1.44]。然后，使用 sort() 方法排序该数组，从而得到数组 [asparagus:3.99, celery:1.29, lettuce:1.49, spinach:1.89, squash:1.44]。

var vegetables:Array = new Array();
vegetables.push(new Vegetable("lettuce", 1.49));
vegetables.push(new Vegetable("spinach", 1.89));
vegetables.push(new Vegetable("asparagus", 3.99));
vegetables.push(new Vegetable("celery", 1.29));
vegetables.push(new Vegetable("squash", 1.44));

trace(vegetables);
// lettuce:1.49, spinach:1.89, asparagus:3.99, celery:1.29, squash:1.44

vegetables.sort();

trace(vegetables);
// asparagus:3.99, celery:1.29, lettuce:1.49, spinach:1.89, squash:1.44

//The following code defines the Vegetable class
class Vegetable {
    private var name:String;
    private var price:Number;

    public function Vegetable(name:String, price:Number) {
        this.name = name;
        this.price = price;
    }

    public function toString():String {
        return " " + name + ":" + price;
    }
}

下例与前一个示例几乎完全相同，唯一不同的是将 sort() 方法与自定义排序函数 (sortOnPrice) 一起使用，该函数按 price 排序，而不是按字母顺序排序。请注意，新函数 getPrice() 将提取 price。

var vegetables:Array = new Array();
vegetables.push(new Vegetable("lettuce", 1.49));
vegetables.push(new Vegetable("spinach", 1.89));
vegetables.push(new Vegetable("asparagus", 3.99));
vegetables.push(new Vegetable("celery", 1.29));
vegetables.push(new Vegetable("squash", 1.44));

trace(vegetables);
// lettuce:1.49, spinach:1.89, asparagus:3.99, celery:1.29, squash:1.44

vegetables.sort(sortOnPrice);

trace(vegetables);
// celery:1.29, squash:1.44, lettuce:1.49, spinach:1.89, asparagus:3.99

function sortOnPrice(a:Vegetable, b:Vegetable):Number {
    var aPrice:Number = a.getPrice();
    var bPrice:Number = b.getPrice();

    if(aPrice > bPrice) {
        return 1;
    } else if(aPrice < bPrice) {
        return -1;
    } else  {
        //aPrice == bPrice
        return 0;
    }
}

// The following code defines the Vegetable class and should be in a separate package.
class Vegetable {
    private var name:String;
    private var price:Number;

    public function Vegetable(name:String, price:Number) {
        this.name = name;
        this.price = price;
    }

    public function getPrice():Number {
        return price;
    }

    public function toString():String {
        return " " + name + ":" + price;
    }
}

下面的代码创建 Array 对象 numbers，其中包含元素 [3,5,100,34,10]。调用 sort() 时如果不带任何参数，将按照字母顺序进行排序，生成不需要的结果 [10,100,3,34,5]。若要对数值进行排序，必须将常数 NUMERIC 传递给 sort() 方法，该方法按以下方式对 numbers 进行排序：[3,5,10,34,100]。

注意：sort() 函数的默认行为是将每个实体作为字符串处理。Array.NUMERIC 参数实际上并没有将其它数据类型转换为 Number 数据类型，它只是允许排序算法识别数字。

var numbers:Array = new Array(3,5,100,34,10);

trace(numbers); // 3,5,100,34,10
numbers.sort();
trace(numbers); // 10,100,3,34,5
numbers.sort(Array.NUMERIC);
trace(numbers); // 3,5,10,34,100

评论

1 楼 leopard0825 2010-05-27  

默认情况下，Array。sort() 按以下方式进行排序：

排序区分大小写（Z 优先于 a）。
按升序排序（a 优先于 b）。
修改该数组以反映排序顺序；在排序后的数组中不按任何特定顺序连续放置具有相同排序字段的多个元素。
元素无论属于何种数据类型，都作为字符串进行排序，所以 100 在 99 之前，这是因为 "1" 的字符串值小于 "9" 的字符串值。