FlexUnit4 简单入门

Flex当前炙手可热的RIA技术，FlexUnit使Flex开发的单元测试成为可能。FlexUnit的目标和思想与JUnit都是差不多的，在此不赘述。FlexUnit也经历了几个版本，目前最新的稳定版是1.0RC版，已经支持了标注式的test，非常好用。

闲言少叙，下面简单介绍一下使用方法。

1.首先下载所需的包，地址：
http://tomorrow009.iteye.com/admin/blogs/579249，我这里使用的是1.0RC版

2.下载后得到是一个项目存档的zip包，如果你安装了FlexBuilder的话，可以直接将这个包导入成为一个Flex project.（这个项目里实际上已经包含了一个示例程序)，你可以直接运行一下FlexUnit4Turnkey.mxml这个Application，就能看到FlexUnit4的运行时界面了。FlexUnit4的测试结果报表是以一个Flash来显示的，这点与JUnit不同。

3. 接下来我们新建一个Flex项目，并尝试在这个项目中使用FlexUnit4. 项目建好之后，我们将FlexUnit4.swc和FlexUnit4UIListener.swc两个库文件拷贝到项目的buildpath中。

4. 先创建一个我们要对其进行测试的业务逻辑类，它和普通的类没有区别.

package my.flexunit
{
	/**
	 * 我们将对这个类的add方法进行测试.  
	 * @author Alex
	 * 
	 */	
	public class SimpleMath
	{
		public function SimpleMath()
		{
		}
		
		public function add(num1:Number,num2:Number):Number
		{
			return num1 + num2;
		}

	}
}

5.接下来我们创建一个SimpleMathTest类用于对SimpleMath做单元测试.

package my.flexunit
{
	import flexunit.framework.TestCase;
	import flexunit.framework.TestSuite;
	import org.flexunit.Assert;
	
	/**
	 * SimpleMath类的测试类 
	 * @author Alex
	 * 
	 */	
	public class SimpleMathTest
	{
		private static var simpleMath:SimpleMath ;
		
		[BeforeClass]
		public static function runBeforeClass():void {   
		    // run for one time before all test cases   
		    simpleMath = new SimpleMath();
		}   
		  
		[AfterClass]  
		public static function runAfterClass():void {   
		    // run for one time after all test cases   
		}   
		
		[Test]  
		public function addition():void {   
		    Assert.assertEquals(12, simpleMath.add(7, 5));   
		}

	}
}

使用过JUnit4的同学一定会对这几个标注[BeforeClass],[AfterClass],[Test]很熟悉，他们和JUnit4中的@Before， @After，@Test的作用是一样的。
所有被标注为[Test]的方法都是一个测试单元。
断言的使用 :  Assert.assertEquals(12, simpleMath.add(7, 5));也是和JUnit很相似的. FlexUnit4提供了多种断言，在此不一一列举.

5. 接下来这一步与JUnit略有不同了，我们需要创建一个Test Suite. 什么是Test Suite呢？ 简单来说，一个TestSuite就是一组测试类的集合。有了这个Test Suite的概念，我们就可以对单元测试进行分组，比如根据业务模块，或者根据代码的架构层次，甚至可以按照开发人员的任务分配情况，进行分组，这样我们在单元测试报表中就可以直观的看到是哪个模块，哪个小组的代码出了问题。 怎样使用测试组呢？ 请看代码

package my.flexunit
{
	
	[Suite]
    [RunWith("org.flexunit.runners.Suite")]
	/**
	 *一个测试组 
	 * @author Alex
	 * 
	 */
	public class MySuite
	{
		public var t1:SimpleMathTest;
		
		public function MySuite()
		{
		}

	}
}

非常简单，首先用两个标注[Suite]，[RunWith("org.flexunit.runners.Suite")]将这个类声明为一个TestSuite，然后只需在类当中声明一个测试类的变量即可，我这里只有一个测试类SimpleMathTest，所以只有一个变量t1，如果有多个的话，就按顺序声明多个。 注意，无需进行实例化。

那么到此为止我们AS代码准备工作就都做完了。

6. 最后，我们创建一个UI程序（在FlexBuilder中新建一个MXML Application），作为入口点，使用它来运行我们的Test Suite并显示测试结果。 代码:

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
				layout="absolute"
				xmlns:flexUnitUIRunner="http://www.adobe.com/2009/flexUnitUIRunner"
				creationComplete="runMe()">

	<mx:Script>
		<![CDATA[
			import org.flexunit.listeners.UIListener;
			import org.flexunit.runner.FlexUnitCore;
			import flexunit.framework.TestSuite;
			import my.flexunit.MySuite;

			private var core:FlexUnitCore;

			public function runMe():void
			{
				core=new FlexUnitCore();
				core.addListener(new UIListener(testRunner));
                                //如果你有多个TestSuite，那么就
                                //core.run(Suite1,Suite2,Suite3 ...)
				core.run(MySuite);

			}
		]]>
	</mx:Script>

	<flexUnitUIRunner:TestRunnerBase id="testRunner"
									 width="100%"
									 height="100%"/>
</mx:Application>

首先我们需要在Application中声明一个flexUnitUIRunner组件，id为testRunner，(它被包含在FlexUnit4UIListener.swc）中。其次在runMe()方法中创建一个FlexUnitCore的实例core，然后用addListener()方法，使testRunner监听core对象，然后core.run（MySuite）方法来依次执行MySuite中的所有测试，(请注意我们这里并没有对MySuite实例化，事实上FlexUnit只是想要读取MySuite中声明的变量列表，这也就是为什么我们无需在MySuite中对变量进行实例化的原因)。每个测试方法的执行都将抛出一个事件，并进而被testRunner监听到，于是显示在界面上。

写完之后右键运行一下这个mxml就可以看到测试结果了。ok,希望对大家有帮助.

评论

4 楼 cfqlove 2010-05-08  

用过Java单元测试的人，会觉得Flex的单元测试好简单的...

3 楼 tomorrow009 2010-05-06  

287854442 写道

必须要顶，这么好的帖子。
楼主是不是直接翻译的英文版的？

谢啦。
这个还真不是直接翻译的。

2 楼 弃天笑 2010-05-05  

已经在用了，支持一下~~
更多好处可以自己去挖掘啦

1 楼 287854442 2010-04-25  

必须要顶，这么好的帖子。
楼主是不是直接翻译的英文版的？