Flash.Util.Dictionary

• 首先来点预备知识 ：

关联数组：也称为"哈希"或"映射"。首先，他是一个数组(废话？:P)。但他不同于一般的数组，它使用"键"而非数字索引来组织存储的值。如同一般数组中每一个数字索引对应一个值一样，关联数组中的每个键都对应一个存储值。关联数组是 Object 类的实例，也就是说每个键都相当于一个属性名称，该键对应的值就是这个属性的值。关联数组是“键、值”对的无序集合(因为对象的属性是没有顺序的)。在代码中，不应期望关联数组的键按特定的顺序排列。

以下示例创建一个名为 monitorInfo 的关联数组，并使用对象文本初始化具有两个“键、值”对的数组：

var monitorInfo:Object = {type:"Flat Panel", resolution:"1600 x 1200"};

trace(monitorInfo["type"], monitorInfo["resolution"]);
// 输出：Flat Panel 1600 x 1200

如果在声明数组时不需要初始化，可以使用 Object 构造函数创建数组，如下所示：

var monitorInfo:Object = new Object();

使用对象文本或 Object 类构造函数创建数组后，可以使用括号运算符 ([]) 或点运算符 (.) 在数组中添加值。以下示例将两个新值添加到 monitorArray 中：

monitorInfo["aspect ratio"] = "16:10"; // 格式错误，请勿使用空格
monitorInfo.colors = "16.7 million";
trace(monitorInfo["aspect ratio"], monitorInfo.colors);
// 输出：16:10 16.7 million

请注意，名为 aspect ratio 的键包含空格字符。也就是说，空格字符可以与括号运算符一起使用，但试图与点运算符一起使用时会生成一个错误。不建议在键名称中使用空格。

第二种关联数组创建方法是使用 Array 构造函数，然后使用括号运算符 ([]) 或点运算符 (.) 将键和值对添加到数组中。如果将关联数组声明为 Array 类型，则将无法使用对象文本初始化该数组。以下示例使用 Array 构造函数创建一个名为 monitorInfo 的关联数组，并添加一个名为 type 的键和一个名为 resolution 的键以及它们的值：

var monitorInfo:Array = new Array();
monitorInfo["type"] = "Flat Panel";
monitorInfo["resolution"] = "1600 x 1200";
trace(monitorInfo["type"], monitorInfo["resolution"]);
// 输出： Flat Panel 1600 x 1200

使用 Array 构造函数创建关联数组没有什么优势。即使使用 Array 构造函数或 Array 数据类型，也不能将 Array 类的 Array.length 属性或任何方法用于关联数组。最好将 Array 构造函数用于创建索引数组，而不建议用于构造关联数组。

• 现在入正题，什么是Dictionary(字典):

Dictionary其实就是具有对象键的关联数组！它使用对象而非字符串作为键！
看例子（用实例解释比啰了八嗦说半天强多啦！）
例如，考虑这样一个应用程序，它要根据 Sprite 对象与特定容器的关联来确定 Sprite 对象的位置（在哪个容器中）。可以使用 Dictionary 对象，将每个 Sprite 对象映射到一个容器。
以下代码创建三个用作 Dictionary 对象的键的 Sprite 对象实例。它为每个键分配了值 GroupA 或 GroupB。值可以是任意数据类型，但在此示例中，GroupA 和 GroupB 均为 Object 类的实例。然后，可以使用属性访问运算符 ([]) 访问与每个键关联的值，如以下代码所示：

import flash.display.Sprite;
import flash.utils.Dictionary;

var groupMap:Dictionary = new Dictionary();

// 要用作键的对象
var spr1:Sprite = new Sprite();
var spr2:Sprite = new Sprite();
var spr3:Sprite = new Sprite();

// 要用作值的对象
var groupA:Object = new Object();
var groupB:Object = new Object();

// 在字典中创建新的“键、值”对。
groupMap[spr1] = groupA;
groupMap[spr2] = groupB;
groupMap[spr3] = groupB;

if (groupMap[spr1] == groupA)
{
trace("spr1 is in groupA");
}
if (groupMap[spr2] == groupB)
{
trace("spr2 is in groupB");
}
if (groupMap[spr3] == groupB)
{
trace("spr3 is in groupB");
}

可以使用 for..in 循环或 for each..in 循环来循环访问 Dictionary 对象的内容。for..in 循环用来基于键进行循环访问；而 for each..in 循环用来基于与每个键关联的值进行循环访问。
可以使用 for..in 循环直接访问 Dictionary 对象的对象键。还可以使用属性访问运算符 ([]) 访问 Dictionary 对象的值。以下代码使用前面的 groupMap 字典示例来说明如何使用 for..in 循环来循环访问 Dictionary 对象：

for (var key:Object in groupMap)
{
trace(key, groupMap[key]);
}

可以使用 for each..in 循环直接访问 Dictionary 对象的值。以下代码也使用 groupMap 字典来说明如何使用 for each..in 循环来循环访问 Dictionary 对象：

for each (var item:Object in groupMap)

{
trace(item);
}

从 myMap 中删除 myObject 键：
delete myMap[myObject];