oracle 动态执行命令execute immediate

可以使用execute immediate来动态执SQL语句和存储过程，在这次的项目中我有一类用“P_InsertInto_”开头的存储过程，后面是表名如：P_InsertInto_AC01、P_InsertInto_AC02等等，用来给AC01、AC02........这些表插入数据的，我们就只能用execute immediate动态执行这些过程，像这样速度和代码编写上就会方便很多了。
这个方法整整研究了一大半天，不容易啊，呵呵。。。。，最终还是成功了！
我对execute immediate的用法的理解用一个实例说明一下，有一个存储过程名为：p_test，它有三个参数，分别为：两个输入参数和一个输出参数，实现过程如：
declare
v_sql varchar2(1000);
c varchar2(1000);
a varchar2(1) :='1';
b number :=1;
begin
--当然动态存储过程可以在这实现了，直接放到v_sql这个变量中就可以了(在这里是一个指定的过程p_test)
v_sql:='begin p_test(:v1,:v2,:v3); end;';
execute immediate v_sql using in '1',in '2',out c;
--或execute immediate v_sql using '1', '2',out c;
dbms_output.put_line(c);
end;
上面我们就实现了动态传递参数和动态存储过程的调用方法。值得注意的是：默认为in，in可省，out不可省！
还有一个值得注意的地方就是：每一个动态（execute immediate）执行的方法都有自己的begin.........end;包住才行呀，如果有多个就这样写：
--第一个
begin
v_sql:='begin p_test1(:v1,:v2,:v3); end;';
execute immediate v_sql using in '1',in '2',out c;
--或execute immediate v_sql using '1', '2',out c;
dbms_output.put_line(c);
end;
--第二个
begin
v_sql:='begin p_test2(:v1,:v2,:v3); end;';
execute immediate v_sql using in '1',in '2',out c;
--或execute immediate v_sql using '1', '2',out c;
dbms_output.put_line(c);
end;
。。。。。。。
--第N个
begin
--
end;

 

 

EXECUTE IMMEDIATE代替了以前Oracle8i中DBMS_SQL package包.它解析并马上执行动态的SQL语句或非运行时创建的PL/SQL块.动态创建和执行SQL语句性能超前，EXECUTE IMMEDIATE的目标在于减小企业费用并获得较高的性能，较之以前它相当容易编码.尽管DBMS_SQL仍然可用，但是推荐使用EXECUTE IMMEDIATE,因为它获的收益在包之上。

使用技巧

 

1. EXECUTE IMMEDIATE不会自动提交一个DML操作，需要手动提交或回滚

如果通过EXECUTE IMMEDIATE处理DML命令，那么需要显式提交或者作为EXECUTE IMMEDIATE自己的一部分. 如果通过EXECUTE IMMEDIATE处理DDL命令,它提交所有以前改变的数据

 

2. 不支持返回多行的查询,这种交互将用临时表来存储记录(参照例子如下)或者用REF cursors.

 

3. 当执行SQL语句时，不要用分号，当执行PL/SQL块时，在其尾部用分号.

 

4. 在Oracle手册中，未详细覆盖这些功能。下面的例子展示了所有用到Execute immediate的可能方面.希望能给你带来方便.

 

5. 对于Forms开发者,当在PL/SQL 8.0.6.3.版本中，Forms 6i不能使用此功能.

 

EXECUTE IMMEDIATE用法例子

 oracle的execute immediate可以动态执行sql语句。下面总结一下这一语句的用法：
1. execute immediate不会自动提交DML事务执行，需要显式提交或者作为execute immediate语句的一部分。（参考如下代码）

1. SQL> create table PEOPLE_T(
2.   2 id number,
3.   3 name varchar(50)
4.   4 );
5.  
6. Table created
7. SQL> set serveroutput on;
8. SQL> declare
9.   2 cnt integer;
10.   3 begin
11.   4 execute immediate 'insert into people_t values(1, ''zhangsan'')';
12.   5 rollback;
13.   6 select count(*) into cnt from people_t;
14.   7 dbms_output.put_line(cnt);
15.   8 end;
16.   9 /
17.  
18. 0
19.  
20. PL/SQL procedure successfully completed
21.  
22. SQL>

上面的代码和结果可以证明，execute immediate并不自动提交DML操作。下面的代码中，我们手动提交：

1. SQL> declare
2.   2 cnt integer;
3.   3 begin
4.   4 execute immediate 'insert into people_t values (2, ''Lisi'')';
5.   5 commit;
6.   6 select count(*) into cnt from people_t;
7.   7 dbms_output.put_line(cnt || ' records after commit');
8.   8 end;
9.   9 /
10.  
11. 1 records after commit
12.  
13. PL/SQL procedure successfully completed

可以看出手动提交后，DML语句的记录才插进表里。当然也可以用下面的方式动态执行提交语句，但是与手动提交没有太大的实际意义：

1. SQL> declare
2.   2 cnt integer;
3.   3 begin
4.   4 execute immediate 'insert into people_t values (3, ''Wangwu'')';
5.   5 execute immediate 'commit';
6.   6 select count(*) into cnt from people_t;
7.   7 dbms_output.put_line(cnt || ' records after commit');
8.   8 end;
9.   9 /
10.  
11. 2 records after commit
12.  
13. PL/SQL procedure successfully completed
14.  
15. SQL>

2. 当执行sql语句时，结尾不需要分号；当执行pl/sql块时，需要用分号结尾。
   
   下面的代码展示了错误的语法：

1. SQL> begin
2.   2 execute immediate 'insert into people_t values (1, ''Zhangsan'');';
3.   3 end;
4.   4 /
5.  
6. begin
7.   execute immediate 'insert into people_t values (1, ''Zhangsan'');';
8. end;
9.  
10. ORA-00911: invalid character
11. ORA-06512: at line 3
12.  
13. SQL>

1. SQL> begin
2.   2 execute immediate 'begin insert into people_t values (1, ''Zhangsan''); end';
3.   3 end;
4.   4 /
5.  
6. begin
7.   execute immediate 'begin insert into people_t values (1, ''Zhangsan''); end';
8. end;
9.  
10. ORA-06550: line 1, column 54:
11. PLS-00103: Encountered the symbol "end-of-file" when expecting one of the following:
12.    ; <an identifier> <a double-quoted delimited-identifier>
13. The symbol ";" was substituted for "end-of-file" to continue.
14. ORA-06512: at line 3
15.  
16. SQL>

3. 在PL/SQL运行DDL语句

begin
execute immediate 'set role all';
end;

 

4. 给动态语句传值(USING 子句)

declare
l_depnam varchar2(20) := 'testing';
l_loc    varchar2(10) := 'Dubai';
begin
execute immediate 'insert into dept values (:1, :2, :3)'
    using 50, l_depnam, l_loc;
commit;
end;

 

5. 从动态语句检索值(INTO子句)

declare
l_cnt    varchar2(20);
begin
execute immediate 'select count(1) from emp'
    into l_cnt;
dbms_output.put_line(l_cnt);
end;

 

6. 动态调用例程.例程中用到的绑定变量参数必须指定参数类型.黓认为IN类型,其它类型必须显式指定

 

declare
l_routin   varchar2(100) := 'gen2161.get_rowcnt';
l_tblnam   varchar2(20) := 'emp';
l_cnt      number;
l_status   varchar2(200);
begin
execute immediate 'begin ' || l_routin || '(:2, :3, :4); end;'
    using in l_tblnam, out l_cnt, in out l_status;

if l_status != 'OK' then
     dbms_output.put_line('error');
end if;
end;

 

7. 将返回值传递到PL/SQL记录类型;同样也可用%rowtype变量

declare
type empdtlrec is record (empno number(4),
                           ename varchar2(20),
                           deptno number(2));
empdtl empdtlrec;
begin
execute immediate 'select empno, ename, deptno ' ||
                   'from emp where empno = 7934'
    into empdtl;
end;

 

8. 传递并检索值.INTO子句用在USING子句前

 

declare
l_dept    pls_integer := 20;
l_nam     varchar2(20);
l_loc     varchar2(20);
begin
execute immediate 'select dname, loc from dept where deptno = :1'
    into l_nam, l_loc
    using l_dept ;
end;

 

9. 多行查询选项.对此选项用insert语句填充临时表，用临时表进行进一步的处理,也可以用REF cursors纠正此缺憾.

declare
l_sal   pls_integer := 2000;
begin
execute immediate 'insert into temp(empno, ename) ' ||
                   '          select empno, ename from emp ' ||
                   '          where sal > :1'
    using l_sal;
commit;
end;

 

       对于处理动态语句,EXECUTE IMMEDIATE比以前可能用到的更容易并且更高效.当意图执行动态语句时，适当地处理异常更加重要.应该关注于捕获所有可能的异常.