windows下oracle自动备份脚本，自动保留30天，并自动压缩

1、利用Oracle的expdp进行备份，

2、可参考另外一篇文章进行学习expdp的使用。

3、备份脚本如下：

 

@echo off
set backhome=E:\backhome
set rarpath="C:\Program Files\WinRAR"
set year=%date:~0,4%
set month=%date:~5,2%
set day=%date:~8,2%
set mydate=%year%%month%%day%
set hhmmss=%time:~0,2%%time:~3,2%%time:~6,2%

expdp.exe andacms/password@orcl schemas=andacms directory=backhome dumpfile=andacms_%mydate%.dmp logfile=expdp_%mydate%.log
rem 利用rar创建压缩文件，压缩率可到10%，压缩完成后，删除源文件,节省磁盘空间。
%rarpath%\Rar.exe a -df %backhome%\andacms_%mydate%.rar %backhome%\andacms_%mydate%.dmp expdp_%mydate%.log


rem 计算指定天数之前的日期 
set DaysAgo=30
rem 假设系统日期的格式为yyyymmdd 
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%%DstMonth%%DstDay%
rem 删除30天之前的旧备份文件。
del /s/q %backhome%\andacms_%DstDate%.rar
goto :eof



:DateToDays %yy% %mm% %dd% days 
setlocal ENABLEEXTENSIONS 
set yy=%1&set mm=%2&set dd=%3 
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%) 
set /a dd=100%dd%%%100,mm=100%mm%%%100 
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2 
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633 
endlocal&set %4=%j%&goto :EOF 

:DaysToDate %days% yy mm dd 
setlocal ENABLEEXTENSIONS 
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a 
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5 
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10 
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%) 
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

 

 

4、将此脚本加入Windows的计划任务中。