第三节：start命令

start命令，可以先查看下帮助
命令行下输入：

start /?

有些命令要结合其他命令才显示出应用效果，在以下讲解中会略提示一下

start 启动另一个窗口运行指定的程序或命令。
start命令大概的形式是:
start ["标题"] [/参数] [命令或程序] [命令或程序的参数]
以[]括起的是可选的,所以可以不写。如直接一个start则多打开一个cmd窗口！

start 与双引号的结合应用
由于批处理的命令多以空格为分隔符来分隔参数，所以双引号最常用的是括起一个带空格的路径令cmd正确解释

@echo off
rem 运行ie 
start "C:\Program Files\Internet Explorer\iexplore.exe"

 由于start有一个"标题"参数,当打开的程序路径带有空格时就必需要指定标题参数

@echo off
rem 打开一个不带空格的路径,可省略双引号
start c:\windows\notepad.exe
rem 打开一个带空格的路径，标题必需要指定，可以是空字符只有双引号
start "" "C:\Program Files\Internet Explorer\iexplore.exe"

 上一节中讲到的"环境变量",环境变量表示一些目录路径以变量的形式使用，而且可以直接使用而不用赋值一些目录的环境变量是含有空格的，如:%userprofile%  路径是 C:\Documents and Settings\用户名

注意: 当使用start打开时也要指定标题

@echo off
rem 看不到但同样有空格的环境变量也要加标题
start "" "%userprofile%\桌面"

 start 的常用参数
start 的常用参数有 /min,/max,/wait,/dpath
MIN 开始时窗口最小化
MAX 开始时窗口最大化
运行一下例子可以清楚看到变化：

@echo off
start /min notepad.exe
pause
start /max notepad.exe

/WAIT 启动应用程序并等候它结束,可以简写为/w
当直接运行一个exe程序时，cmd会等待程序进程结束时才会执行下一句，而使用start打开程序不带wait参数时，不会等待程序结束直接运行下一句命令。

@echo off
rem 直接打开一个记事本
echo 请手动关闭记事本才可以进行下一句
notepad.exe
rem 使用start打开
start notepad.exe
echo start打开不用等待
pause
echo 使用wait参数要等待结束才会进行下一句echo
start /w notepad.exe
echo 这记事本进程终于结束了
pause

 /dpath 参数是指定起始目录，一些执行文件需要指定起始目录才可以正常运行，多用于运行一些游戏或程序中的执行文件。

@echo off
rem 指定起始目录为"E:\office"
start /dE:\office E:\office\WINWORD.EXE