Oracle_PL_ SQL_ 教程：错误和异常

--######################################--
--错误和异常
--王林 2012.07.06
--######################################--

--三种编译错误消息：
/*
一种是错误发生在前一语句行时指向语句行的第一列；另一种是在错误发生在同一行时指向错误发生的列或后一列；还有一种是指向声明块错误，在消息底部提供实际错误的行号。
*/

--######################################--
--1.错误发生在前一行，通常是由于缺少语句终止符END保留字前缺少词汇单元，这里指分号
BEGIN
    DBMS_OUTPUT.put_line( 'Hello World' )
END;
--
ORA-06550: line 4, column 1:
PLS-00103: Encountered the symbol "END" when expecting one of the following:

   := . ( % ;
The symbol ";" was substituted for "END" to continue.
 
SQL> 

--######################################--
--2.错误发生在当前行，变量B前缺少词汇单元
DECLARE 
    a NUMBER := 0;
    b NUMBER;
    c NUMBER;
BEGIN
    c := a b;
END;
--
ORA-06550: line 7, column 12:
PLS-00103: Encountered the symbol "B" when expecting one of the following:

   . ( * @ % & = - + ; < / > at in is mod remainder not rem
   <an exponent (**)> <> or != or ~= >= <= <> and or like like2
   like4 likec between || multiset member submultiset
The symbol "." was substituted for "B" to continue.
 
SQL> 

--######################################--
--3.应出现赋值运算符的地方出现了比较运算符
DECLARE 
    a NUMBER;
BEGIN
    a = 1; 
END;
--
ORA-06550: line 5, column 7:
PLS-00103: Encountered the symbol "=" when expecting one of the following:

   := . ( @ % ;
The symbol ":= was inserted before "=" to continue.
 
SQL>

--######################################--
--4.错误发生在声明块，只是说明声明块中有错误
DECLARE
    a CHAR := 'AB';
BEGIN
    DBMS_OUTPUT.put_line( '[' || a || ']' );
END;
--
ORA-06502: PL/SQL: numeric or value error: character string buffer too small
ORA-06512: at line 3
 
SQL> 

--######################################--
--一、异常类型和作用域
--1.局部异常块捕获和管理局部错误，异常块只管理那种错误，其它异常将被忽略并被抛给SQL*Plus会话。
DECLARE 
    a VARCHAR2 (1);
    b VARCHAR2 (2) := 'ab';
BEGIN
    a := b;
EXCEPTION
    WHEN value_error THEN
        DBMS_OUTPUT.put_line('you are wrong.');
END;

--2.内部块中引发的错误，将被外部块异常处理程序捕获。
DECLARE
    a NUMBER;
BEGIN
    DECLARE
        b VARCHAR2 (2);
    BEGIN
        --引发的错误是NO_DATA_FOUND异常
        SELECT 1 INTO b
          FROM dual
         WHERE 1 = 2;
    --引发的错误是赋值错误
    a := b;
    EXCEPTION
        --内部块只检查VALUE_ERROR异常，因为他是特殊的捕获块
        WHEN value_error THEN
            DBMS_OUTPUT.put_line( 'inner wrong.' );
    END;
EXCEPTION
    --外部块捕获普通的OTHERS异常
    WHEN OTHERS THEN
        DBMS_OUTPUT.put_line( 'outer wrong.['  
                              || SQLERRM
                              || ']'
                            );
END;
    
--3.在无异常的情况下可手动引发用户自定义的异常。
DECLARE
    a NUMBER;  
    e EXCEPTION;
BEGIN
    DECLARE
        b VARCHAR2 （2） ：= 'AB';
    BEGIN
        --RAISE语句将控制传递给局部异常处理程序。
        RAISE e;
    EXCEPTION
        WHEN OTHERS THEN
            --试图将多字符字面值赋给一个字符变量，这引发value_error异常。
            a := b;
            DBMS_OUTPUT.put_line( '1 wrong.' );
    END;
EXCEPTION
    WHEN OTHERS THEN
        DBMS_OUTPUT.put_line( '2 wrong.['  
                              || SQLCODE
                              || ']'
                            );
END;

--4.声明块异常
--声明块中的运行时赋值错误不是由局部异常块捕获
DECLARE
    a VARCHAR2 (1) := '&1';
BEGIN
    DBMS_OUTPUT.put_line( 'value :' ||a );
EXCEPTION
    --不起作用
    WHEN OTHERS THEN
        DBMS_OUTPUT.put_line( 'local exception caught.' );
END;                
--
--将声明错误封装到另一个PL/SQL中
--如果赋值两个字符的字符串 这一错误将被外部异常块捕获
BEGIN
    DECLARE
        a VARCHAR2 (1) := '&1';
    BEGIN
        DBMS_OUTPUT.put_line( '1 ' || a);
    EXCEPTION
        WHEN OTHERS THEN
            DBMS_OUTPUT.put_line( '2 ');
    END;
EXCEPTION
    WHEN OTHERS THEN
        DBMS_OUTPUT.put_line( '3 ');
END;

--######################################--
--二、用户自定义异常
--声明exception变量时有两种选择：声明变量并用名称来引用他和声明变量并将他与有效的Oracle错误代码映射。
--前者要求使用普通的OTHERS异常捕获用户自定义异常，后者要为单独的错误构建特定的WHEN块。
--通过调用RAISE_APPLICATION_ERROR函数可构建动态异常。在构建动态异常时可以使用-20000到-20999范围
--的数字。如果使用动态异常，就在运行时指派错误消息，他们也不要求事先声明exception变量。通过声明异常变量可以
--提高动态异常的有用性，同时，他们也增加了捕获异常的方式。
--
--1.声明用户自定义的异常
DECLARE
    e EXCEPTION;
BEGIN
    RAISE e;
    DBMS_OUTPUT.put_line( 'can not get there ');
EXCEPTION
    WHEN OTHERS THEN
        --默认情况下，所有用户定义的异常都只有一个SQLCODE值1
        IF SQLCODE = 1 THEN
            DBMS_OUTPUT.put_line( 'This is a [ ' || SQLERRM || ' ]');
        END IF;
END;

--2.定义一个Excepiton变量并将该异常映射到错误号
--两步的声明过程可以将声明异常并将他映射到数字
DECLARE
    a VARCHAR2 (20);
    --第一步声明Exception变量；
    invalid_userenv_parameter EXCEPTION;
    --第二步声明PRAGMA。 他是个编译指令，使用它命令编译器以不同的方式执行一些任务。
    --EXCEPTION_INIT调用的第一个参数为用户定义的EXCEPTION变量，第二个为有效的错误号。
    PRAGMA EXCEPTION_INIT(invalid_userenv_parameter , -2003);
BEGIN
    a := SYS_CONTEXT( 'USERENV' , 'PROXY_PUSHER' );
EXCEPTION
    WHEN invalid_userenv_parameter THEN
        DBMS_OUTPUT.put_line(SQLERRM);
END;
    
--3.动态的用户定义的异常
--动态的用户定义的异常用于引发异常、赋值和管理是否添加新的错误到错误列表（也就是错误堆栈）
--动态异常函数的原型：
rasie_application_error( error_number     --接受-20000--20999范围的错误号。如果提供其他值引发ORA-21000错误
                         , error_message  --错误消息
                         [ , keep_errors] --可选 默认FALSE 是否将错误信息添加到任意已有的错误堆栈
                       );

--没有事先声明用户定义的exception变量的情况下引发一个动态异常
BEGIN
    raise_application_error(-20001 , 'A not too oritional message');
EXCEPTION 
    WHEN OTHERS THEN
        DBMS_OUTPUT.put_line(SQLERRM);
END;

--声明一个exception变量，将用户的错误代码映射到exception变量，然后动态设置消息。
DECLARE
    e EXCEPTION;
    PRAGMA EXCEPTION_INIT(e,-20001);
BEGIN
    raise_application_error(-20001 , 'A less than original message.');
EXCEPTION
    WHEN e THEN
        DBMS_OUTPUT.put_line(SQLERRM);
END;