批处理for命令详解

FOR /F %%i IN (file) DO command

file为文件名，按照官方的说法是，for会依次将file中的文件打开，并且在进行到下一个文件之前将每个文件读取到内存，按照每一行分成一个一个的元素，忽略空白的行，看个例子。
假如文件a.txt中有如下内容：

第1行第1列 第1行第2列 第1行第3列
第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列

你想显示a.txt中的内容，会用什么命令呢？当然是type，type a.txt
for也可以完成同样的命令：
for /f %%i in (a.txt) do echo %%i
还是先从括号执行，因为含有参数/f,所以for会先打开a.txt，然后读出a.txt里面的所有内容，把它作为一个集合，并且以每一行作为一个元素，所以会产生这样的集合，

{"第1行第1列 第1行第2列 第1行第3列"， //第一个元素
"第2行第1列 第2行第2列 第2行第3列"， //第二个元素
"第3行第1列 第3行第2列 第3行第3列"} //第三个元素

集合中只有3个元素，同样用%%i依次代替每个元素，然后执行do后面的命令。
具体过程：
用%%i代替"第1行第1列 第1行第2列 第1行第3列"，执行do后面的echo %%i，显示"第1行第1列 第1行第2列 第1行第3列"，
用%%i代替"第2行第1列 第2行第2列 第2行第3列"，执行echo %%i，显示"第2行第1列 第2行第2列 第2行第3列"，
依次，直到每个元素都代替完为止。
为了加强理解/f的作用，请执行一下两个命令，对比即可明白：
for /f %%i in (a.txt) do echo %%i //这个会显示a.txt里面的内容，因为/f的作用，会读出a.txt中的内容。
for %%i in (a.txt) do echo %%i //而这个只会显示a.txt这个名字，并不会读取其中的内容。
通过上面的学习，我们发现for /f会默认以每一行来作为一个元素，但是如果我们还想把每一行再分解更小的内容，该怎么办呢？不用担心，for命令还为我们提供了更详细的参数，使我们将每一行分为更小的元素成为可能。
它们就是：delims和tokens
delims 用来告诉for每一行应该拿什么作为分隔符，默认的分隔符是空格和tab键
比如，还是上面的文件，我们执行下面的命令：
for /f "delims= " %%i in (a.txt) do echo %%i
显示的结果是：

第1行第1列
第2行第1列
第3行第1列

为什么是这样的呢。因为这里有了delims这个参数，=后面有一个空格，意思是再将每个元素以空格分割，默认是只取分割之后的第一个元素。
执行过程是：
将第一个元素"第1行第1列 第1行第2列 第1行第3列"分成三个元素："第1行第1列" "第1行第2列" "第1行第3列"，它默认只取第一个，即"第1行第1列"，然后执行do后面的命令，依次类推。
但是这样还是有局限的，如果我们想要每一行的第二列元素，那又如何呢？
这时候，tokens跳出来说，我能做到。
它的作用就是当你通过delims将每一行分为更小的元素时，由它来控制要取哪一个或哪几个。
还是上面的例子，执行如下命令：
for /f "tokens=2 delims= " %%i in (a.txt) do echo %%i
执行结果：

第1行第2列
第2行第2列
第3行第2列

如果要显示第三列，那就换成tokens=3。
同时tokens支持通配符*，以及限定范围。
如果要显示第二列和第三列，则换成tokens=2,3或tokens=2-3,如果还有更多的则为：tokens=2-10之类的。
此时的命令为：

for /f "tokens=2,3 delims= " %%i in (a.txt) do echo %%i %%j

怎么多出一个%%j？
这是因为你的tokens后面要取每一行的两列，用%%i来替换第二列，用%%j来替换第三列。
并且必须是按照英文字母顺序排列的，%%j不能换成%%k，因为i后面是j
执行结果为：

第1行第2列 第1行第3列
第2行第2列 第2行第3列
第3行第2列 第3行第3列

对以通配符*，就是把这一行全部或者这一行的剩余部分当作一个元素了。
比如：
for /f "tokens=* delims= " %%i in (a.txt) do echo %%i
执行结果为：

第1行第1列 第1行第2列 第1行第3列
第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列

其实就跟for /f %%i in (a.txt) do echo %%i的执行结果是一样的。
再如：
for /f "tokens=2,* delims= " %%i in (a.txt) do echo %%i %%j
执行结果为：

第1行第2列 第1行第3列
第2行第2列 第2行第3列
第3行第2列 第3行第3列

用%%i代替第二列，用%%j代替剩余的所有
最后还有skip合eol，这俩个简单，skip就是要忽略文件的前多少行，而eol用来指定当一行以什么符号开始时，就忽略它。
比如：
for /f "skip=2 tokens=*" %%i in (a.txt) do echo %%i
结果为:

第3行第1列 第3行第2列 第3行第3列

用skip来告诉for跳过前两行。
如果不加tokens=*的话，执行结果为：
第3行第1列
不知道怎么回事。

再如，当a.txt内容变成：

.第1行第1列 第1行第2列 第1行第3列
第2行第1列 第2行第2列 第2行第3列
.第3行第1列 第3行第2列 第3行第3列

执行for /f "eol=. tokens=*" %%i in (a.txt) do echo %%i结果是：

第2行第1列 第2行第2列 第2行第3列

用eol来告诉for忽略以"."开头的行。同样也必须加tokens=*，否则只会显示"第3行第1列"

for命令的一些bug分析

1、关于冒号：当某行内容以 : 打头时，用 for /f "tokens=1* delims=:" %%i in ('findstr /n .* test.txt') do echo.%%j 会把:过滤掉；
2、关于分号：findstr .* test.txt 可以把以分号打头的行完整显示出来，但是，用在for语句中就不能找到了，必须加上参数/n才可以，似乎是for语句会把以分号打头的行当作注释内容忽略掉，好象不是findstr的错；而不放在for语句中的 type、more和findstr都是可以的；

解决问题1和问题2的方案有：

稍微复杂一点的：
@echo off
:: 不会忽略空行
for /f "delims=" %%i in ('findstr /n .* test.txt') do (
set "str=%%i"
call set "str=%%str:*:=%%"
call echo "%%str%%"
)
pause

最简洁的：
@echo off
:: 此代码会忽略空行
for /f "delims= eol=" %%i in (test.txt) do echo %%i
pause

3、在for扩展中，%%~si 表示扩充的路径只含短文件名，但是在以下的测试过程中，却发现真正的情况并非如此：
测试环境：
--------------------------------------------------------------------------------
D:/abcdefg hijk/abcd efgh.txt
D:/abcdefg hijk/te st.txt
测试代码：
--------------------------------------------------------------------------------
@echo off
for /f "delims=" %%i in ('dir /a /b *.txt') do echo %%~si
pause
测试结果：
--------------------------------------------------------------------------------
D:/ABCDEF~1/ABCDEF~1.TXT
D:/ABCDEF~1/TEST~1.TXTtxt
看到测试结果的最后一条记录了吗？居然扩展到了 TEST~1.TXTtxt ！
总结了一下出错的情形，似乎是这样的：当路径中有超过一个的地方因为目录名超过11个字符而扩充到短文件名的时候，文件名+后缀名少于11个字符且带空格的文件就会发生扩展错误。