[转]倒放音乐

package 
{
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.SampleDataEvent;
        import flash.media.Sound;
        import flash.utils.ByteArray;
        /**
         * @author FLASH023
         * @date 2010-7-31 18:27
        **/
        public class PSound extends Sprite  
        {
                private var len:uint;
                private var position:int;
                private var sound:Sound;
                private var soundData:ByteArray;
                public function PSound():void {
                        stage?init(null):addEventListener (Event.ADDED_TO_STAGE, init);
                }
                private function init(e:Event ):void {
                        var tempsound:RPSound=new RPSound  ;
                        soundData =new ByteArray  ;
                        tempsound.extract(soundData,999999999);
                        len=soundData.length;
                        position=int(len/8)-8;
                        sound = new Sound  ;
                        sound.addEventListener(SampleDataEvent.SAMPLE_DATA,onSampledata);
                        sound.play();
                        //
                        removeEventListener(Event.ADDED_TO_STAGE, init);
                }
                private function onSampledata(e:SampleDataEvent):void {
                        var _i:int=2048;
                        while (_i--) {
                                soundData.position=position*8;
                                e.data.writeFloat(soundData.readFloat());
                                e.data.writeFloat(soundData.readFloat());
                                position--;                
                                if (position<0) {
                                        trace("声音播放完了");
                                        return;
                                        //position=int(len/8)-8;
                                }
                        }
                        //trace(position);
                }
        }
        
}